//===== Hercules Script ======================================
//= Healer
//===== By: ==================================================
//= Euphy
//===== Current Version: =====================================
//= 1.2
//===== Description: =========================================
//= Basic healer script.
//===== Additional Comments: =================================
//= 1.0 Initial script.
//= 1.1 Aligned coordinates with @go.
//= 1.2 Fix variables and character stuck at healing
//============================================================

//@unloadnpc Nurse
//@loadnpc npc/amatsu/features/healer.txt

prontera,141,180,0	script	Nurse	4_F_NURSE,{
	if(questprogress(31004) == 1 && countitem(30108) > 0 ){
		cutin "malaya_nursea01",2;	
		mes .npc$;
		mes "Greetings. I am nurse Shamma.  I take my duties very seriously, so I don't have time to idle chat.";
		mes "Oh... my mistake! I did not realize that you were new in town.";
		mes "I'm constantly busy. A nurse work with adventurers is never done!.";
		next;
		mes .npc$;
		mes "A physician and master healer, I am able to heal you effeciently!";
		mes "Thanks to my years of training, such instant healing is no big deal.";
		next;
		mes .npc$;
		mes "If you need me to heal your HP quickly and fully, I can do that! I can also heal SP as well - though that is more difficult.";
		mes "I do charge for my services, but I assure you that they are worth every last Zeny.";
		mes "Come and speak to me any time you need quick and effecient healing.";
		nov_train2++;
		switch (BaseLevel){
			case 1: getexp 9,0; break;
			case 2: getexp 16,0; break;
			case 3: getexp 25,0; break;
			case 4: getexp 36,0; break;
			case 5: getexp 77,0; break;
			case 6: getexp 112,0; break;
			case 7: getexp 153,0; break;
			case 8: getexp 200,0; break;
			case 9: getexp 253,0; break;
			case 10: getexp 320,0; break;
			case 11: getexp 385,0; break;
			case 12: getexp 490,0; break;
			case 13: getexp 585,0; break;
			case 14: getexp 700,0; break;
			case 15: getexp 830,0; break;
			case 16: getexp 970,0; break;
			case 17: getexp 1120,0; break;
			case 18: getexp 1260,0; break;
			case 19: getexp 1420,0; break;
		}
		switch (JobLevel) {
			case 1: getexp 0,10; break;
			case 2: getexp 0,18; break;
			case 3: getexp 0,28; break;
			case 4: getexp 0,40; break;
			case 5: getexp 0,91; break;
			case 6: getexp 0,151; break;
			case 7: getexp 0,205; break;
			case 8: getexp 0,258; break;
			case 9: getexp 0,340; break;
		}
		delitem 30108,countitem(30108);
		if(nov_train2 == 3){
			next;
			mes .npc$;
			mes "Well then, I think that you've completed your mission!";
			mes "Go back to ^ff0000Hannibal^000000 now to continue your training quest";
			completequest(31004);
			setquest(31005);
			cutin "",255;
			close;
		}
		cutin "",255;		
		close;

	}
	.@price = 0;	// Zeny required for heal
	.@Buffs = 0;	// Also buff players? (1: yes / 0: no)
	.@Delay = 0;	// Heal delay, in seconds
	if (@HD > gettimetick(2)) end;
	if (.@price) {
		message strcharinfo(PC_NAME),"Healing costs "+.@price+" Zeny.";
		if (Zeny < .@price) end;
		if(select("^0055FFHeal^000000", "^777777Cancel^000000") == 2) close;
		Zeny -= .@price;
	}
	specialeffect(EF_HEAL2, AREA, playerattached()); percentheal 100,100;
	if (.@Buffs) {
		specialeffect(EF_INCAGILITY, AREA, playerattached()); sc_start SC_INC_AGI,240000,10;
		specialeffect(EF_BLESSING, AREA, playerattached()); sc_start SC_BLESSING,240000,10;
	}
	if (.@Delay) @HD = gettimetick(2)+.@Delay;
	end;
OnInit:
	questinfo(QTYPE_JOB, 1);
	setquestinfo(QINFO_JOB, Job_Novice);
	setquestinfo(QINFO_QUEST, 31004, 1);
	setquestinfo(QINFO_ITEM, 30108, 1,1);
	.npc$ = "[ ^ff0000Nurse^000000 ]";
	end;
}


