morocc,68,91,1	script	Eloise	4_F_CAPEGIRL,{
	if (questprogress(30303) == 1 || questprogress(30304) == 1 ){
		mes "[ ^ff0000Eloise^000000 ]";
		mes "Please go to Amatsu to see Jake.";
		close;
	}
	/* Bring the meal */
	if(questprogress(30309) == 1) {
		mes "[ ^ff0000Eloise^000000 ]";
		mes "Did you bring the Chilli Chicken?";
		next;
		switch(select("Yes, Here!!!","What's with these feathers?")){
			case 1: // Yes, Here!!!
				mes "[ ^ff0000Eloise^000000 ]";
				mes "Thank you.  I really missed this Chilli Chicken";
				close;				
			case 2: // What's with these feathers?";
				mes "[ ^ff0000Eloise^000000 ]";
				mes "Vincent used to know a man who could take the feathers and make a really nice hat.  If you fancy making one, go see Mr. Jojoquin in Alberta and tell him I sent you.  But remember, it's a secret.";
				completequest(30309);
				setquest(30310);
				close;
		}
		close;
	}
	/* She is happy already for the meal */	
	if (questprogress(30309) == 2 ){
		mes "[ ^ff0000Eloise^000000 ]";
		mes "Thank you for bringing a wonderful meal to me.";
		close;
	}
	if (questprogress(30304) == 2 ){
		mes "[ ^ff0000Eloise^000000 ]";
		mes "I'm aching for good meal. I haven't had a nice dinner.";
		close;
	}

	mes "[ ^ff0000Eloise^000000 ]";
	mes "Excuse me, I am Eloise.";
	mes "Could you help me? I'm aching for good meal. I haven't had a nice dinner.";
	next;
	switch(select(
		"That's awful. Sure, I'll help.:"+
		"Sorry, I'm busy"
	)) {
	case 1: //That's awful. Sure, I'll help.
		mes "[ ^ff0000Eloise^000000 ]";	
		mes "That's great. My husband Vincent used to go fishing.  He would never bring home any fish but would always bring me home my favorite dish Chilli Chicken.";
		mes "He used to go fishing with Jake and Leonard. I don't know what happen to Leonard, but last I heard Jake moved to Amatsu.";
		mes "If you find him I'm sure he will tell you where Vincent got the Chilli Chicken from.";
		setquest(30303);
		close;
	case 2: //Sorry, I'm busy
		close;
	}
}

amatsu,83,142,4	script	Jake	4_M_LGTPOOR,{
	if( questprogress(30304) == 1 || questprogress(30306) == 2 ) {
		mes "[ ^ff0000Jake^000000 ]";	
		mes "Did you forget it already? I said you need to take the chicken from the island near Izlude and give it to Leonard at the Prontera restaurant.";
		close;
	}
	if(questprogress(30303) == 1 ){
		mes "[ ^ff0000Jake^000000 ]";	
		mes "I'm sorry to hear about Vincent.  I left morocc."; 
		mes "Ofcourse I will help you. Me, Vincent and Leonard used to fish off the coast of Izlude... but never caught any fish, haha.";
		next;
		mes "[ ^ff0000Jake^000000 ]";	
		mes "One day, we stopped for lunch on a nearby island.  We found the best and juicy chicken we have ever tasted.";
		next;
		mes "[ ^ff0000Jake^000000 ]";	
		mes "Leonard used to cook it using his secret recipe and Vincent would always take some home for Eloise.";
		next;
		mes "[ ^ff0000Jake^000000 ]";	
		mes "If you find the chicken take it to Leonard who I believe works at Prontera restaurant. Tell him I sent you.";
		completequest(30303);
		setquest(30304);
		close;
	} else {
		mes "[ ^ff0000Jake^000000 ]";	
		mes "This place is so nice. Would you agree?";
		close;	
	}
}

izlu2dun,172,132,1	script	Free Range Chicken	4_NFCOCK,{
	if (questprogress(30304) == 1){
		mes "*Cluck Cluck... Squawk!!!*";
		mes "^051A30You've captured the Juicy Chicken.^000000";
		completequest(30304);
		setquest(30305);
	} else {	
		mes "*Cluck Cluck... Squawk!!!*";
	}			
	close;
}

lou_in02,45,128,3	script	Leonard	4_M_BRZ_MAN1,{
	disable_items;
	if(questprogress(30305) == 0) {
		mes "[ ^ff0000Leonard^000000 ]";
		mes "I'm so tired. Leave me alone";
		close;
	} else if(questprogress(30305) == 1 ) {
		mes "^051A30You explained to Leonard about Eloise and Jake^000000";
		next;
		mes "[ ^ff0000Leonard^000000 ]";
		mes "Wow, I'm sorry to hear about Vincent. Ofcourse I will cook Eloise's favorite dish. I just need a chicken and few other items.";
		next;
		mes "[ ^ff0000Leonard^000000 ]";
		mes "Bring me these items:";
		mes "1x "+getitemname(Matchstick);
		mes "50x "+getitemname(Live_Coal);
		mes "1x "+getitemname(Rainbow_Carrot);
		mes "5x "+getitemname(Chilli);
		completequest(30305);
		setquest(30306);
		close;
	}

	/* Why are you still here? I'm done with you. Bring that dish to Eloise */
	if(questprogress(30309) >= 1 ) {
		mes "[ ^ff0000Leonard^000000 ]";
		mes "Bring that Chilli Chicken to Eloise.";
		close;
	}

	/* Wait for 1 hour. I'm still cooking :D */
	if(questprogress(30308,PLAYTIME) == 1 ){
		mes "[ ^ff0000Leonard^000000 ]";
		mes "I'm still cooking the dish.  Please comeback later";
		close;
	}

	/* Complete The Dish */
	if(questprogress(30308,PLAYTIME) == 2 ){	
		mes "[ ^ff0000Leonard^000000 ]";
		mes "Here is it!!!";
		mes "I have also given you the feathers.  I don't know why Vincent used to always take home the feathers.";
		next;
		mes "[ ^ff0000Leonard^000000 ]";
		mes "Bring this dish back to Eloise. I'm very sure she will love it.";
		completequest(30308);
		setquest(30309);					
		close;
	}
	
	/* First attempt to light matchstick */
	if(questprogress(30306) == 1 ){
		if(countitem(Matchstick) > 0 && countitem(Live_Coal) > 49 && countitem(Rainbow_Carrot) > 0 && countitem(Chilli) > 4){
			mes "[ ^ff0000Leonard^000000 ]";
			mes "Very well, let me light this Match Sticks";
			delitem Matchstick,1;
			next;
			mes "^051A30As Leonard light the Match Stick, It breaks.^000000";
			next;
			mes "[ ^ff0000Leonard^000000 ]";
			mes "Oh my!!! I broke the Match Sticks, do you have extra one?";
			completequest(30306);
			setquest(30307);				
			close;
		} else {
			mes "[ ^ff0000Leonard^000000 ]";
			mes "Bring me these items:";
			mes "1x "+getitemname(Matchstick);
			mes "50x "+getitemname(Live_Coal);
			mes "1x "+getitemname(Rainbow_Carrot);
			mes "5x "+getitemname(Chilli);
			close;
		}
	}

	/* Bring another matchstick */
	if(questprogress(30307) == 1 ){
		if(countitem(Matchstick) > 0 && countitem(Live_Coal) > 49 && countitem(Rainbow_Carrot) > 0 && countitem(Chilli) > 4){
			if(questprogress(30307) == 1){
				mes "[ ^ff0000Leonard^000000 ]";
				mes "Nice, you brought me another matchstick.  I hope this will not break again.";
				next;
				mes "[ ^ff0000Leonard^000000 ]";
				mes "Wew, it did light the coal. Now you have to wait until I finish cooking this wonderful meal.";
				delitem Matchstick,1;
				delitem Live_Coal,50;
				delitem Rainbow_Carrot,1;
				delitem Chilli,5;
				completequest(30307);
				setquest(30308);
				close;
			}
		} else {
			mes "[ ^ff0000Leonard^000000 ]";
			mes "Bring me these items:";
			mes "1x "+getitemname(Matchstick);
			mes "50x "+getitemname(Live_Coal);
			mes "1x "+getitemname(Rainbow_Carrot);
			mes "5x "+getitemname(Chilli);
			close;
		}
	}
}

alberta_in,133,46,3	script	Mr. Jojoquin	4_M_05,{
	disable_items;	
	if(questprogress(30310) < 1) {
		mes "[ ^ff0000Mr. Jojoquin^000000 ]";
		mes "I'm busy. Leave me alone";
		close;
	} else if(questprogress(30310) == 1 ) {
		mes "^051A30You explained to Mr. Jojoquin about Eloise and the feathers^000000";
		next;
		mes "[ ^ff0000Mr. Jojoquin^000000 ]";
		mes "Wow, I'm sorry to hear about Vincent. I missed that guy.  Ofcourse I will make you the special hat. I just need few other items.";
		next;
		mes "[ ^ff0000Mr. Jojoquin^000000 ]";
		mes "Bring me these items:";
		mes "10x "+getitemname(Animals_Skin);
		mes "10x "+getitemname(Sticky_Mucus);
		mes "10x "+getitemname(Horseshoe);
		mes "1x "+getitemname(Bill_Of_Birds);
		mes "1x "+getitemname(Cap_);
		mes "1x "+getitemname(Lariat);
		completequest(30310);
		setquest(30311);
		close;
	}
	if (questprogress(30311) == 1 ){
		if (countitem(Animals_Skin) > 9 && countitem(Sticky_Mucus) > 9 && countitem(Horseshoe) > 9 && countitem(Bill_Of_Birds) > 0 && countitem(Cap_) > 0 && countitem(Lariat) > 0){
			mes "[ ^ff0000Mr. Jojoquin^000000 ]";
			mes "Wonderful, wear it with pride.";
			delitem Animals_Skin,10;
			delitem Sticky_Mucus,10;
			delitem Horseshoe,10;
			delitem Bill_Of_Birds,1;
			delitem Cap_,1;
			delitem Lariat,1;
			getitem Chicken_Hat,1;
			chanmsg("#system",""+strcharinfo(PC_NAME)+" has created "+getitemname(5431)+"[1]");
			completequest(30311);
			close;				
		} else {
			mes "[ ^ff0000Mr. Jojoquin^000000 ]";
			mes "Bring me these items:";
			mes "10x "+getitemname(Animals_Skin);
			mes "10x "+getitemname(Sticky_Mucus);
			mes "10x "+getitemname(Horseshoe);
			mes "1x "+getitemname(Bill_Of_Birds);
			mes "1x "+getitemname(Cap_);
			mes "1x "+getitemname(Lariat);
			close;
		}
	}
	if (questprogress(30311) == 2){
		mes "[ ^ff0000Mr. Jojoquin^000000 ]";
		mes "Happy with your Chicken Hat?";
		close;
	}

end;

}
