
moc_pryd01,139,130,4	script	Dead Man	4_M_DSTMANDEAD,{
	if(questprogress(30507) == 2) {
		mes "...";
		close;
	}
	if(questprogress(30507) == 1){
		mes "[ ^304D57"+strcharinfo(PC_NAME)+"^000000 ]";
		mes ("Hmmm, this message looks important.  I should try getting it to its destination.");
		close;
	}
	mes ("^ff0000You find a dead man bleeding and lying on the floor, there seems to be something in his hand.  Would you like to inspect it?");
	next;
	if (select("Yes","No") == 1) {
		mes ("^ff0000You find a paper saying:");
		mes ("^304D57'Beware, they discovered the existence of the stone and are trying to steal it.  Do not let them have it.'");
		mes ("^ff0000The paper has a symbol you are unable to recognize.");
		next;
		mes "[ ^304D57"+strcharinfo(PC_NAME)+"^000000 ]";
		mes ("Hmmm, this message looks important.  I should try getting it to its destination.");
		setquest(30507);
		close;
	} else {
		mes "[ ^304D57"+strcharinfo(PC_NAME)+"^000000 ]";
		mes ("Maybe I should stay away from this.");
		close;
	}
		
}
geffen_in,17,121,4	script	Bernard	4_M_JOB_WIZARD,{
	disable_items;
	if(questprogress(30511) == 1) {
		mes "[ ^ff0000Bernard^000000 ]";
		mes ("That spell is really useful, but it is costly.  I wonder what he needs to protect, but that is none of my business.");
		close;
	}
	if(questprogress(30510) == 1) {
		if(countitem(Royal_Jelly) > 49 && countitem(Aloe) > 4 && countitem(Anodyne) > 9){
			mes "[ ^ff0000Bernard^000000 ]";
			mes ("Thank you so much.  Tell him the spell is in the page 457 of the book I gave him.");
			delitem Royal_Jelly,50;
			delitem Aloe,5;
			delitem Anodyne,10;			
			changequest(30510,30511);				
			close;
		} else {
			mes "[ ^ff0000Bernard^000000 ]";
			mes ("What are you waiting for?  The sooner you get the items, the sooner you get the spells.  Please don't leave me waiting for the medicine ingredients.  Remember:");
			next;
			mes "[ ^ff0000Bernard^000000 ]";
			mes ("50x "+getitemname(Royal_Jelly));
			mes ("5x "+getitemname(Aloe));
			mes ("10x "+getitemname(Anodyne));
			close;	
		}		
	}
	if(questprogress(30509) == 1){
		mes "[ ^ff0000Bernard^000000 ]";
		mes ("Hmmm, I sense that you are looking for me.  I am Bernard what do you want?");
		next;
		mes "[ ^304D57"+strcharinfo(PC_NAME)+"^000000 ]";
		mes ("Your bird-brained student sent me to ask you for the spell to prevent objects from being tracked through magic.");
		next;
		mes "[ ^ff0000Bernard^000000 ]";
		mes ("Darius?  Hahaha, he always forgets everything.  Hmmm, would you mind doing me a favor first?  My head hurts a lot recently.  May you please get some ingredients to make some medicine?  The ingredients are:");
		next;
		changequest(30509,30510);	
		mes "[ ^ff0000Bernard^000000 ]";
		mes ("50x "+getitemname(Royal_Jelly));
		mes ("5x "+getitemname(Aloe));
		mes ("10x "+getitemname(Anodyne));
		close;
	}
}

moc_fild12,157,371,0	script	Bandith#1	1_M_MOC_LORD,{
end;
}

moc_fild12,161,370,0	script	Bandith#2	1_M_MOC_LORD,{
end;
}

moc_fild12,155,376,4	script	Bandith#3	1_M_MOC_LORD,{
end;
}

moc_fild12,159,373,4	script	Bandith Leader	1_M_MOC_LORD,3,3,{
end;

OnTouch:
	if(questprogress(30513) == 1) {
		hideoffnpc "Bandith Leader";
		hideoffnpc "Bandith#1";
		hideoffnpc "Bandith#2";
		hideoffnpc "Bandith#3";
		mes "[ ^ff0000Bandith Leader^000000 ]";
		mes ("I found you, the Desert Riders need to be more careful with such powerful artifacts.  Hand me the stone without putting a fight and we will spare your life.");
		next;
		mes "[ ^304D57"+strcharinfo(PC_NAME)+"^000000 ]";
		mes ("Alright, but please do not harm me!");
		next;
		mes "[ ^ff0000Bandith Leader^000000 ]";
		mes ("Hand us the stone fast!");
		next;
		mes "[ ^304D57"+strcharinfo(PC_NAME)+"^000000 ]";
		mes ("There you go.");
		next;
		mes "[ ^ff0000Bandith Leader^000000 ]";
		mes ("Okay, let's go now!");
		next;
		mes ("^ff0000As the bandits run you see one of them left some red piece of cloth behind, better take it to Darius for him to inspect it.");
		changequest(30513,30514);
		hideonnpc "Bandith Leader";
		hideonnpc "Bandith#1";
		hideonnpc "Bandith#2";
		hideonnpc "Bandith#3";
		close;
	}
	end;	

OnInit:
	hideonnpc "Bandith Leader";
	hideonnpc "Bandith#1";
	hideonnpc "Bandith#2";
	hideonnpc "Bandith#3";
	end;
}

morocc,41,182,4	script	Weird Looking Guy	4_M_GREATPO,{
	disable_items;
	if(questprogress(30515) == 1) {
		mes "[ ^ff0000Darius^000000 ]";
		mes ("Want me to make you the scarf?");
		next;
		if (select("Yes","No") == 1) {
			if(countitem(Ganster_Mask) > 0 && countitem(Gang_Scarf) > 0 && countitem(Red_Scarf) > 199 && Zeny > 499999 ){
				mes "[ ^ff0000Darius^000000 ]";	
				delitem Ganster_Mask,1;
				delitem Gang_Scarf,1;
				delitem Red_Scarf,200;
				Zeny -= 500000;
				getitem Gang_Scarf_E,1;
				completequest(30515);
				close;
			} else {
				mes "[ ^ff0000Darius^000000 ]";	
				mes ("It seems you do not have the items required.  Remember:");
				mes ("1x "+getitemname(Ganster_Mask));
				mes ("1x "+getitemname(Gang_Scarf));
				mes ("200x "+getitemname(Red_Scarf));
				mes ("500,000 Zeny");	
				close;
			}	
		} else {
			mes "[ ^ff0000Darius^000000 ]";
			mes ("Well, maybe another day.");
			close;	
		}	
	}
	if(questprogress(30514) == 1) {
		mes "[ ^ff0000Darius^000000 ]";
		mes ("So, how did it go?  You seem unharmed, so I guess it was well.  The stone is on it's way, thank you so much.  Now they will try to use it and will discover it is a fake one.  Your help is really appreciated.");
		next;
		mes "[ ^304D57"+strcharinfo(PC_NAME)+"^000000 ]";
		mes ("Yes, it all went well.  While they were escaping they left this piece of cloth behind, it looks damage.");
		next;
		mes "[ ^ff0000Darius^000000 ]";
		mes ("Well, there is nothing special about it.  If you will bring me the following materials, I can transform into a scarf you can wear on your mouth.");
		next;
		mes "[ ^ff0000Darius^000000 ]";
		mes ("1x "+getitemname(Ganster_Mask));
		mes ("1x "+getitemname(Gang_Scarf));
		mes ("200x "+getitemname(Red_Scarf));
		mes ("500,000 Zeny");	
		changequest(30514,30515);		
		close;
	}
	if(questprogress(30513) == 1) {
		mes "[ ^ff0000Darius^000000 ]";
		mes ("What are you waiting for?  Exit through the southern entrance and distract them while I deliver the real rock!");
		close;	
	}
	if(questprogress(30512,PLAYTIME) == 2){
		mes "[ ^ff0000Darius^000000 ]";
		mes ("Let's hurry, the Morocc Marauders could be here any moment now.  While I hide this I want you to lure them so they don't follow me.  Take this fake stone and make them ambush you.  I think they might be expecting me to take it to Comodo through the southern entrance.");
		next;
		mes "[ ^ff0000Darius^000000 ]";
		mes ("I will send it through a secret passage with one of the members of the Desert Riders to our headquarters in one of the limits of Sograt Desert, once it gets there it will be safe.");
		changequest(30512,30513);
		close;
	} else if (questprogress(30512,PLAYTIME) == 1) {
		mes "[ ^ff0000Darius^000000 ]";
		mes ("Wait more time please, I still need to finish the spell.");
		close;
	}
	if(questprogress(30511) == 1) {
		mes "[ ^ff0000Darius^000000 ]";
		mes ("Page 457...  Let me look at it.  I wonder why didn't Bernard make an index when he created this book.  For him it doesn't matter, he remembers everything he has heard and read, but us normal people can't be expected to know where is every single spell contained.  Here it is!!!  Good, let me do it.  I will be ready in an hour so.  Please talk me by then.");
		changequest(30511,30512);
		close;
	}
	if(questprogress(30509) == 1){
		mes "[ ^ff0000Darius^000000 ]";
		mes ("I knew I should have written down that spell.  Well, It shouldn't be hard to convince him to tell you how to do it.");
		close;
	}
	if(questprogress(30508) == 1){	
		if(countitem(Worn_Out_Scroll) > 99 && countitem(Red_Muffler) > 0){
			mes "[ ^ff0000Darius^000000 ]";
			mes ("Good, thank you for bringing thse things.  If I were younger I would have gone to get these myself, but now age has diminished my strenght.  Ok, let's get started with this spell.");
			next;
			mes "[ ^ff0000Darius^000000 ]";
			mes ("Hummmmmmm.. err.. I forgot how to do this.  May I ask you another favor?  Please go to geffen and look for Bernard in the Geffen bar please?  He taught me this spell, just tell him his bird-brained student forgot something else.  Ask him for the spell to prevent objects from being tracked through magic.");
			delitem Worn_Out_Scroll,100;
			delitem Red_Muffler,1;
			changequest(30508,30509);
			close;
		} else {
			mes "[ ^ff0000Darius^000000 ]";
			mes ("What are you doing?  Bring that item fast, there is no time to lose.  Remember:");
			mes ("100x "+getitemname(Worn_Out_Scroll));
			mes ("1x "+getitemname(Red_Muffler));
			close;	
		}
	}
	if(questprogress(30507) == 1){
		if(!@talkagain){
			mes "[ ^ff0000???^000000 ]";
			mes ("What do you have there? That paper has the symbol of the Dessert Riders, is it destined to me?");
			next;
			mes ("^ff0000	You show him the letter.");
			next;
			mes "[ ^ff0000???^000000 ]";
			mes ("Hmmm, I should do something about this.  If such an important letter was trusted to you, it must mean I should trust you too.  Would you help me protect the stone? It may be risky.  I will give you some time to think of it.");
			@talkagain = 1;
			close;
		} else {
			mes "[ ^ff0000???^000000 ]";
			mes ("So, will you help me protect the stone?");
			next;
			if (select("Yes","No") == 1) {
				mes "[ ^ff0000Darius^000000 ]";
				mes ("Before telling you what we need to do please let me introduce myself, my name is Darius, co-leader of the Dessert Riders, were you told abuse us?");
				next;
				mes "[ ^304D57"+strcharinfo(PC_NAME)+"^000000 ]";
				mes ("No, I was just sent to deliver this message to you.");
				next;
				mes "[ ^ff0000Darius^000000 ]";
				mes ("Well, the Dessert Riders are a group founded to protect the city of Morroc from gang called the Morroc Marauders, who are dedicated to steal powerful artifacts in order to have power.  Currently I am in hold of a powerful stone capable of controlling a powerful beast if some lives are sacrificed  and some spells recited.");
				next;
				mes "[ ^ff0000Darius^000000 ]";
				mes ("There is no way we can let them get hold of it.  If they do, they would conquer Morroc in no time and from here conquer slowly the rest of Rune-Midgarts.  I need you to get some things I am missing to put a spell on it to prevent them from tracking it with magic.  I will need:");
				next;
				mes "[ ^ff0000Darius^000000 ]";
				mes ("100x "+getitemname(Worn_Out_Scroll));
				mes ("1x "+getitemname(Red_Muffler));
				next;
				mes "[ ^304D57"+strcharinfo(PC_NAME)+"^000000 ]";
				mes ("OK, I will try to get those items.");
				completequest(30507);
				setquest(30508);
				close;	
			} else {
				mes "[ ^ff0000???^000000 ]";
				mes ("Well, then I will have to do this by myself.  If you change your mind please come back to me.");
				close;
			}
			
		}
	}	
end;
}