
prt_in,72,107,4	script	Dilios	4_M_HUOLDARMY,{
	if (questprogress(30288) == 2 ){
		if(isequipped(5782)){
			mes "[ ^ff0000Dilios^000000 ]";
			mes "For Sparta.  for freedom, to the death!";
		} else {
			mes "[ ^ff0000Dilios^000000 ]";
			mes "You have fought well, wear that Spartan's Helm proud.";
		}
		close;
	}
	/* Bring the heart */
	if (questprogress(30286) == 1 ){
		mes "[ ^ff0000Dilios^000000 ]";
		mes "Astonishing!  You indeed fight not only with your head but with your heart.  With like any good Spartan you'll need equipment.  See the local forger.";
		changequest(30286,30287);
		close;
	}
	if(questprogress(30287) == 1){
		mes "[ ^ff0000Dilios^000000 ]";
		mes "See the local forger at Geffen.";
		close;
	}
	if(!questprogress(30264)){
		mes "*An old man stares into the fireplace*";
		setquest(30264);
		close;
	}
	if(questprogress(30264) == 1) {
		mes "[ ^ff0000Dilios^000000 ]";
		mes "Can I help you with something adventurer?";
		next;
		switch(select("^3131FFWho are you?^000000", "^3131FFNo, I'm fine.^000000")) {
		case 1: // Who are you?
			mes "[ ^ff0000Dilios^000000 ]";
			mes "I'm Dilios, former Spartan Soldier.";
			next;
			if (select("Spartan?") == 1) {
				mes "[ ^ff0000Dilios^000000 ]";
				mes "The old ones say we Spartans are descendent from Hercules himself.  We did what we trained to do, what we are breed to do, what we were born to do!  Our only occupation is to fight.";
				next;
				if (select("I want to be a Spartan Soldier!.","That's stupid old man.") == 1) {
					mes "[ ^ff0000Dilios^000000 ]";
					mes "^304D57*Laughs*^000000 Not just anyone can be a Spartan Soldier.";
					next;
					if (select("Please, give me a chance!") == 1) {
						mes "[ ^ff0000Dilios^000000 ]";
						mes "Spartan's true strength is the warrior next to him. So give respect and honor to him, and it will be returned to you.  First, you fight with your head then your heart.";
						completequest(30264);
						setquest(30265);
						close;
					}
				} else {
					mes "[ ^ff0000Dilios^000000 ]";
					mes "Than leave.";
					close;
				}
			}	
		case 2: // No, I'm fine.";
			mes "[ ^ff0000Dilios^000000 ]";
			mes "Farewell then.";
			close;
		}
	}
	/* Must kill Vagabond Wolf */
	if(questprogress(30265,HUNTING) == 1) {
		mes "[ ^ff0000Dilios^000000 ]";
		mes "I'm sorry but you haven't proven your worth. Go kill that Vagabound Wolf.";
		close;
	} else if(questprogress(30265,HUNTING) == 2 ) {
		mes "[ ^ff0000Dilios^000000 ]";
		mes "Well done. Your training can begin.";
		next;
		mes "[ ^ff0000Dilios^000000 ]";
		mes "Spartans are descended from the mighty Hercules.  Hercules was a mighty warrior.  What weapon did Hercules use?  Bring that item to symbolize your wisdom.";
		changequest(30265,30266);
		close;
	}
	if(questprogress(30266) == 1){
		if(countitem(Club_) > 0){
			mes "[ ^ff0000Dilios^000000 ]";
			mes "Well done.  Hercules armed himself with a wooden club.";
			next;
			mes "[ ^ff0000Dilios^000000 ]";
			mes "So far you are doing well.  However this is just the beginning.";
			mes "The soldier not only fights with their head but their heart as well.";
			mes "Speak with the oracle of Delphi about how you can prove your heart is of a soldier.";
			delitem Club_,1;
			changequest(30266,30267);
			close;
		} else {
			mes "[ ^ff0000Dilios^000000 ]";
			mes "I'm sorry but you did not brought me Hercules weapon.";
			close;
		}
	}
	if(questprogress(30267)== 1){
		mes "[ ^ff0000Dilios^000000 ]";
		mes "Find Oracle of Delphi.  She should be inside Prontera church.";
		close;
	}
}

prt_church,88,125,4	script	Oracle of Delphi	4_HUMAN_GERUTOO,{
	disable_items;
	if(!questprogress(30264)){
		mes "[ ^ff0000Oracle of Delphi^000000 ]";
		mes "Don't disturb me, I'm meditating.";
		close;
	}
	if(questprogress(30267) == 1){
		mes "[ ^304D57"+strcharinfo(PC_NAME)+"^000000 ]";
		mes "Hello?";
		next;
		mes "[ ^ff0000Oracle of Delphi^000000 ]";
		mes "Ah did Dilios send you?  Another bloodlust hungry soldier.";
		mes "You all the same!  Murderers and thugs!  Senseless killing deserves punishment!";
		next;
		mes "[ ^304D57"+strcharinfo(PC_NAME)+"^000000 ]";
		mes "Please, I'm seeking the heart of a spartan soldier.  I don't wish to kill the innocent.";
		next;
		mes "[ ^ff0000Oracle of Delphi^000000 ]";
		mes "Is that so?  Well have you killed?";
		next;
		if (select("Yes") == 1) {
			mes "[ ^ff0000Oracle of Delphi^000000 ]";
			mes "I'm sorry but I can't help you then... useless...";
			mes "You finish the 12 labors of repentance.";
			next;
			if (select("The very same Hercules did?") == 1) {
				mes "[ ^ff0000Oracle of Delphi^000000 ]";
				mes "Yes, the very same.  If you finish them, I will reward you with the heart you seek.";
				mes "Are you ready to begin?";
				next;
				if (select("Yes") == 1) {
					mes "[ ^ff0000Oracle of Delphi^000000 ]";
					mes "1.  Conquer and deliver the Gryphon, a monstrous hawk.  As proof bring me the "+getitemname(Talon_Of_Griffin)+".";
					changequest(30267,30268); // Bring the Talon of Griffon from Gryphon		
					close;
				}
			}
		}
	}
	// 1st Task - Bring the Citrin from Chimera
	if (questprogress(30268) == 1 ){
		if(countitem(Talon_Of_Griffin) > 0){
			delitem Talon_Of_Griffin,1;
			mes "[ ^ff0000Oracle of Delphi^000000 ]";
			mes "Well done soldier.  Your next task is:";
			mes "2.  Kill the Multi-Head Hydra.  Bring me the solution dropped from its tentacles, "+getitemname(Detrimindexta)+".";
			changequest(30268,30269);  // Detrimindextra
			close;
		} else {
			mes "[ ^ff0000Oracle of Delphi^000000 ]";
			mes "Deliver the "+getitemname(Talon_Of_Griffin)+", dropped by Gryphon.";
			close;
		}
	}
	// 2nd Task - Detrimindextra
	if (questprogress(30269) == 1 ){
		if(countitem(Detrimindexta) > 0){
			mes "[ ^ff0000Oracle of Delphi^000000 ]";
			mes "This will do.  For your next task:";  
			mes "3.  Bring back the "+getitemname(Gaoats_Skin)+" of Goat, a ravaging brute.";
			delitem Detrimindexta,1;
			changequest(30269,30270);  // Antelope Skin
			close;
		} else {
			mes "[ ^ff0000Oracle of Delphi^000000 ]";
			mes "Kill the Hydra and bring me the solution of "+getitemname(Detrimindexta)+".";
			close;
		}
	}
	// 3rd Task - Antelope Skin
	if (questprogress(30270) == 1 ){
		if(countitem(Gaoats_Skin) > 0){
			mes "[ ^ff0000Oracle of Delphi^000000 ]";
			mes "Thank you.  Now:";  
			mes "4.  Catch the Savage Boar.  Bring the "+getitemname(Anodyne)+" from its tusk.";
			delitem Gaoats_Skin,1;
			changequest(30270,30271); // Anodyne
			close;
		} else {
			mes "[ ^ff0000Oracle of Delphi^000000 ]";
			mes "You need to bring me "+getitemname(Gaoats_Skin)+".";
			close;
		}
	}
	// 4th Task - Anodyne
	if (questprogress(30271) == 1 ){
		if(countitem(Anodyne) > 0){
			mes "[ ^ff0000Oracle of Delphi^000000 ]";
			mes "Great!  Your next task is:";  
			mes "5.  Clean out the massive stables of Augeas at Archer Village.";
			delitem Anodyne,1;
			changequest(30271,30272); // Clean Stable
			close;
		} else {
			mes "[ ^ff0000Oracle of Delphi^000000 ]";
			mes "Where is my "+getitemname(Anodyne)+"?.";
			close;
		}
	}
	if (questprogress(30272) == 1 ){
		mes "[ ^ff0000Oracle of Delphi^000000 ]";
		mes "See Augeas in Archer Village! He has a task for you.";
		close;
	}


	// 5th Task - Report Cleaning of Stables
	if (questprogress(30274) == 1 ){
		mes "[ ^ff0000Oracle of Delphi^000000 ]";
		mes "Amazing you're half way through your task.  The next one is simple.";
		mes "6.  Scare off and kill the metal-feathered Harpy.  Bring a "+getitemname(Harpys_Claw)+".";
		changequest(30274,30275); // Harpy Talon
		close;
	}

	// 6th Task - Harpy Talon
	if (questprogress(30275) == 1 ){
		if(countitem(Harpys_Claw) > 0) {
			mes "[ ^ff0000Oracle of Delphi^000000 ]";
			mes "Wonderful, your next task is:";  
			mes "7.  Capture Majoruros, bring me its "+getitemname(Silver_Ring)+".";
			delitem Harpys_Claw,1;
			changequest(30275,30276); // Silver Ring		 
			close;
		} else {
			mes "[ ^ff0000Oracle of Delphi^000000 ]";
			mes "Bring me a "+getitemname(Harpys_Claw)+".";
			close;
		}
	}
	// 7th Task - Silver Ring
	if (questprogress(30276) == 1 ){
		if(countitem(Silver_Ring) > 0){
			mes "[ ^ff0000Oracle of Delphi^000000 ]";
			mes "Thank you, the next task is:";  
			mes "8.  Do something about those pesky Nightmares.  Slay and bring me an "+getitemname(Old_Blue_Box)+".";
			delitem Silver_Ring,1;
			changequest(30276,30277); // Old Blue Box
			close;
		} else {
			mes "[ ^ff0000Oracle of Delphi^000000 ]";
			mes "Where's my "+getitemname(Silver_Ring)+"?.";
			close;
		}
	}
	// 8th Task - Old Blue Box
	if (questprogress(30277) == 1 ){
		if(countitem(Old_Blue_Box) > 0){
			mes "[ ^ff0000Oracle of Delphi^000000 ]";
			mes "Great! Now for something more simple:";  
			mes "9.  Get the Girdle of Hippolyta, queen of the Umbala Tribe.";
			delitem Old_Blue_Box,1;
			changequest(30277,30278); // Gridle of Hippolta
			close;
		} else {
			mes "[ ^ff0000Oracle of Delphi^000000 ]";
			mes "Slay those spesky Nightmares and bring me an "+getitemname(Old_Blue_Box)+".";
			close;
		}
	}
	if (questprogress(30278) == 1 ){
		mes "[ ^ff0000Oracle of Delphi^000000 ]";
		mes "Retrive the girdle from Hippolyta.  I heard she resides in nature with the Utan tribe.";
		close;
	}

	// 9th Task (b) - Girdle of Hippolyta
	if (questprogress(30279) == 1 ) {
		mes "[ ^ff0000Oracle of Delphi^000000 ]";
		mes "Good job, your next task is the opposite:";  
		mes "10.  Steal the cattle of Morroc.";
		changequest(30279,30280);
		close;
	}
	if (questprogress(30280) == 1 ) {
		mes "[ ^ff0000Oracle of Delphi^000000 ]";
		mes "You need to steal the cattle of Morroc.";  
		close;
	}

	// 10th Task (c) - Steal Cattle of Morroc
	if (questprogress(30281) == 1 ){
		mes "[ ^ff0000Oracle of Delphi^000000 ]";
		mes "Almost done.  Your next task is: "; 
		mes "11.  Bring back the golden apples of the Hesperides.  It can be found in Gonryun City.";
		changequest(30281,30282);
		close;
	}
	// 11th Task - Golden Apple
	if (questprogress(30282) == 1 ){
		mes "[ ^ff0000Oracle of Delphi^000000 ]";
		mes "Get me the golden apple from Gonryun City.";
		close;
	}
	if(questprogress(30283) == 1 ){
		mes "[ ^ff0000Oracle of Delphi^000000 ]";	
		mes "Well done. Your final task to prove your courage and worth:";
		mes "12.  Go down to the Magma Underworld and bring back Cerberus, chief Hound of Hades.";
		changequest(30283,30284);
		close;
	}
	if (questprogress(30284) == 1 ){
		mes "[ ^ff0000Oracle of Delphi^000000 ]";
		mes "Bring back Cerberus from Magma Underworld.";
		close;
	}
	if(questprogress(30285) == 1){
		mes "[ ^ff0000Oracle of Delphi^000000 ]";
		mes "You have proven your worth soldier.  Return to Dilios.";
		changequest(30285,30286);
		close;
	}
	if (questprogress(30286) == 1 ){
		mes "[ ^ff0000Oracle of Delphi^000000 ]";
		mes "Youre almost there. Return to Dilios.";
		close;
	}


end;

}

pay_arche,99,134,4	script	Augeas	4_M_NOV_HUNT,{
	/* archer village */
	if (questprogress(30272) == 1 ){
		mes "[ ^ff0000Augeas^000000 ]";
		mes "So you're here to clean eh?";
		mes "Bring me 100 "+getitemname(Holy_Water)+" to purify the stables.";
		changequest(30272,30273);
		close;
	}
	// 5th Task - 100x Holy Water
	if (questprogress(30273) == 1 ){
		if(countitem(Holy_Water) > 99){
			mes "[ ^ff0000Augeas^000000 ]";
			mes "Thank you, the stables are now clean.  Give my regards to Delphi.";  
			delitem Holy_Water,100;
			changequest(30273,30274);
			close;
		} else {
			mes "[ ^ff0000Augeas^000000 ]";
			mes "I don't have all day! Bring me the "+getitemname(Holy_Water)+".";
			close;
		}
	}
	if (questprogress(30374) == 1 || !questprogress(30374) ) {
		mes "[ ^ff0000Augeas^000000 ]";
		mes "How will I get these stable clean?";
		close;
	}

end;

}

pay_arche,103,135,4	script	Cow	4_WHITE_COW,{
	mes "Booo~Boooo!!!";
	mes "Boooboobooo Booo~~";
	mes "Booobo Boooo";
	close;
end;
}

umbala,144,224,4	script	Hippolyta	4_M_UMOLDMAN,{
	/* Umbala */
	// 9th Task - Girdle of Hippolyta
	if (questprogress(30278) == 1 ){
		mes "[ ^ff0000Hippolyta^000000 ]";
		mes "Here you go!!!";
		mes "^304D57*you received the girdle*^000000";	
		changequest(30278,30279);	
		close;
	} else {
		mes "[ ^ff0000Hippolyta^000000 ]";
		mes "Greetings!!!";
		close;
	}
end;
}

moc_ruins,118,145,4	script	Cow#1	4_WHITE_COW,{
	if (questprogress(30280) == 1 ) {
		if (@follows1){
			mes "^304D57. . .^000000";
		} else {
			mes "...^304D57*follows*^000000";
			@follows1 = 1;
			@follows += 1;
			if (@follows == 3){
				next;
				mes "[ ^304D57"+strcharinfo(PC_NAME)+"^000000 ]";
				mes "I guess that's all.";
				changequest(30280,30281);
				close;				
			}
		}
		close;
	}	
end;
}
moc_ruins,121,150,4	script	Cow#2	4_WHITE_COW,{
	if (questprogress(30280) == 1 ) {
		if (@follows2){
			mes "^304D57. . .^000000";
		} else {
			mes "...^304D57*follows*^000000";
			@follows2 = 1;
			@follows += 1;
			if (@follows == 3){
				next;
				mes "[ ^304D57"+strcharinfo(PC_NAME)+"^000000 ]";
				mes "I guess that's all.";
				changequest(30280,30281);
				close;				
			}
		}
		close;
	}	
end;
}
moc_ruins,118,150,4	script	Cow#3	4_WHITE_COW,{
	if (questprogress(30280) == 1 ) {
		if (@follows3){
			mes "^304D57. . .^000000";
		} else {
			mes "...^304D57*follows*^000000";
			@follows3 = 1;
			@follows += 1;
			if (@follows == 3){
				next;
				mes "[ ^304D57"+strcharinfo(PC_NAME)+"^000000 ]";
				mes "I guess that's all.";
				changequest(30280,30281);
				close;				
			}
		}
		close;
	}	
end;
}

gonryun,91,173,0	script	Glimmers	HIDDEN_NPC,{
	if (questprogress(30282) == 1 ){
		mes "^304D57*Something golden glimmers in the branches*^000000";
		next;
		if (select("Shake the tree.") == 1) {	
			changequest(30282,30283);
		}
		close;
	}

end;
}

mag_dun02,222,178,4	script	Cerberus	4_DOG01,{
	if (questprogress(30284) == 1 ) {
		mes "[ ^ff0000Cerberus^000000 ]";
		mes "Woof! Woof! ^304D57*licks*^000000";
		next;
		mes "[ ^304D57"+strcharinfo(PC_NAME)+"^000000 ]";
		mes "You're Cerberus? What a cute doggie!  Come with me please.";
		changequest(30284,30285);
		close;
	}	
end;
}

geffen,176,52,4	script	Hephaestus	2_M_OLDBLSMITH,{
	disable_items;
	if (questprogress(30287) == 1 ){
		mes "[ ^ff0000Hephaestus^000000 ]";
		mes "^304D57*Looks up from his work*^000000";
		mes "Can I help you?";
		next;
		if (select("Show him the Heart of Hercules") == 1) {	
			mes "[ ^ff0000Hephaestus^000000 ]";
			mes "Well now, another soldier?  You're gonna need your helmet. I can fashion that heart into Hopilite Helmet.  If you bring me the following items:";
			mes "^ff00002x "+getitemname(Gold)+"^000000";
			mes "^ff00005x "+getitemname(Scarlet_Dyestuffs)+"^000000";
			mes "^ff00001x "+getitemname(Helm_)+"^000000";
			mes "^ff00001x "+getitemname(Iron_Cane)+"^000000";
			changequest(30287,30288);
			close;
		}
	}
	if (questprogress(30288) == 1 ){
		if (countitem(Gold) > 1 && countitem(Scarlet_Dyestuffs) > 4 && countitem(Helm_) > 0 && countitem(Iron_Cane) > 0){
			mes "[ ^ff0000Hephaestus^000000 ]";
			mes "Use it well.";
			delitem Gold,2;
			delitem Scarlet_Dyestuffs,5;
			delitem Helm_,1;
			delitem Iron_Cane,1;
			getitem Hoplite_Helmet,1;
			completequest(30288);	
			close;
		} else {
			mes "[ ^ff0000Hephaestus^000000 ]";
			mes "You don't have all the items you need:";
			mes "^ff00002x "+getitemname(Gold)+"^000000";
			mes "^ff00005x "+getitemname(Scarlet_Dyestuffs)+"^000000";
			mes "^ff00001x "+getitemname(Helm_)+"^000000";
			mes "^ff00001x "+getitemname(Iron_Cane)+"^000000";
			close;
		}
	}
	if (questprogress(30288) == 2 ){
		mes "[ ^ff0000Hephaestus^000000 ]";
		mes "Use it well.";
		close;
	}			
end;
}
