//================= Hercules Script =======================================
//=       _   _                     _
//=      | | | |                   | |
//=      | |_| | ___ _ __ ___ _   _| | ___  ___
//=      |  _  |/ _ \ '__/ __| | | | |/ _ \/ __|
//=      | | | |  __/ | | (__| |_| | |  __/\__ \
//=      \_| |_/\___|_|  \___|\__,_|_|\___||___/
//================= License ===============================================
//= This file is part of Hercules.
//= http://herc.ws - http://github.com/HerculesWS/Hercules
//=
//= Copyright (C) 2012-2015  Hercules Dev Team
//= Copyright (C)  Kisuka
//= Copyright (C)  L0ne_W0lf
//= Copyright (C)  Vicious
//= Copyright (C)  Samuray22
//= Copyright (C)  Lupus
//= Copyright (C)  Muad_Dib(The Prometheus Project)
//=
//= Hercules is free software: you can redistribute it and/or modify
//= it under the terms of the GNU General Public License as published by
//= the Free Software Foundation, either version 3 of the License, or
//= (at your option) any later version.
//=
//= This program is distributed in the hope that it will be useful,
//= but WITHOUT ANY WARRANTY; without even the implied warranty of
//= MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//= GNU General Public License for more details.
//=
//= You should have received a copy of the GNU General Public License
//= along with this program.  If not, see <http://www.gnu.org/licenses/>.
//=========================================================================
//= Bard Job Quest
//================= Description ===========================================
//= Job quest for Bard class
//================= Current Version =======================================
//= 2.6
//=========================================================================

//== Ayealo ================================================
comodo,226,123,5	script	Wandering Bard	2_M_BARD_ORIENT,{
	if(Upper == 1) {
		mes "[Lalo]";
		mes "Chosen ones who are destined to become Gods";
		mes "are so many in this era";
		mes "but they never realise their fate while alive.";
		mes "They end up to become ordinary men...";
		next;
		mes "[Lalo]";
		mes "Wind and Clouds, please send this message to them,";
		mes "who pursue food, clothing, shelter and wealth.";
		mes "Tell them they are wasting their time...";
		mes "Tell them they forget the most important goal of the life...";
		close2;
		cutin "job_bard_aiolo01",255;
		end;
	}
	else if(BaseJob != Job_Archer) {
		if(BaseJob == Job_Bard) {
			mes "[Lalo]";
			mes "Ooh hey! How's your singing these days?";
			mes "I wonder if your voice got any better.";
			next;
			mes "[Lalo]";
			mes "You don't forget to spread good news in each town, right?";
			mes "And don't forget to learn new songs, too...";
			next;
			mes "[Lalo]";
			mes "Never forget to have a positive attitude and the meaning of joy.";
			mes "Our songs are supposed to deliver happiness and joy to everyone.";
		}
		else if(Class == Job_Novice) {
			cutin "job_bard_aiolo01",2;
			mes "[Lalo]";
			mes "The sadness that overcomes my heart.. ";
			mes "It will not reside..";
			mes "Is this the reason behind my troubles,";
			mes "is this why I am weak,";
			mes "This must be why I cannot seem to forget you...";
			next;
			mes "[Lalo]";
			mes "Oh, sorry. I didn't see you because I was concentrating on writing some lyrics.";
			mes "Do you want to listen to my songs? Shall I sing a song for you?";
			next;
			mes "[Lalo]";
			mes "Heh... try asking someone else.";
			mes "I'm trying to compose a new song.";
		}
		else {
			cutin "job_bard_aiolo01",2;
			mes "[Lalo]";
			mes "Lalala, lalala. Beautiful Comodo.";
			mes "Always full of happy moments~";
			next;
			mes "[Lalo]";
			if (Sex == SEX_MALE) {
				mes "Forget about your worries~";
				mes "And enjoy everything~";
			}
			else mes "Cute lady, shall we dance~";
			mes "Youth never repeats itself~";
		}
		close2;
		cutin "job_bard_aiolo01",255;
		end;
	}
	else if(BARD_Q == 0) {
		cutin "job_bard_aiolo01",2;
		mes "[Lalo]";
		if (Sex == SEX_MALE)
			mes "Hi! Delightful Archer.";
		else
			mes "Hello! Beautiful Archer Lady.";
		mes "How can a wanderer like me help you?";
		next;
		switch(select("You have a nice voice.", "Could you sing for me, please?", "Nothing.")) {
		case 1:
			mes "[Lalo]";
			mes "Hahaha! Of course!";
			mes "if you sing with a happy heart, your voice always gets better.";
			next;
			mes "[Lalo]";
			mes "But, to Bards your voice is your life.";
			mes "Sometimes your voice will go, but you must be careful.";
			break;

		case 2:
			mes "[Lalo]";
			mes "A song... let's see.";
			mes "Ok, I got one...";
			next;
			mes "[Lalo]";
			mes "I'll sing.. Drums of War.";
			mes "*ehem...*cough...gag..mememememe...";
			mes "1, 2, 3, 4...";
			next;
			mes "^000088The sound of horses galloping over the horizon";
			mes "The dust that covers the distant sun";
			mes "When thousands of eyes open in the night sky";
			mes "The castle's fire will burn with power.^000000";
			next;
			mes "^000088I can hear.. the beating of my heart.";
			mes "I can feel.. the blood rushing through my veins.";
			mes ".. and the weight of my armor.";
			mes "I can see.. my enemies.^000000";
			next;
			mes "^000088Louder, louder louder..";
			mes "Give strength to the warriors!";
			mes "Higher, higher, higher..";
			mes "This day will never come again!^000000";
			next;
			mes "^000088Shake the sky and roar through the land.";
			mes "Make my heart pound again!";
			mes "Let the trumpets sound, and castle walls ring.";
			mes "This moment will never come again!^000000";
			next;
			mes "[Lalo]";
			mes "Hmm... that's always a good song to sing.";
			mes "How was it? Don't you think it's a nice song?";
			next;
			if (select("Yes, it was very nice.", "No, not really...") == 1) {
				mes "[Lalo]";
				mes "Thanks! if you enjoyed my song, it makes me happy, too.";
				next;
				if (Sex == SEX_MALE && JobLevel > 39) {
					mes "[Lalo]";
					mes "It would be nice if more people went around and sang...";
					mes "Well, it's quite ok as it is now... hmmhmm.";
					BARD_Q = 1;
					setquest 3000;
					close2;
					cutin "job_bard_aiolo01",255;
					end;
				}
				mes "[Lalo]";
				mes "if you ever want to hear my song again, just ask.";
				close2;
				cutin "job_bard_aiolo01",255;
				end;
			}
			cutin "job_bard_aiolo02",2;
			mes "[Lalo]";
			mes "Hmm... Did I lose my senses, I'll have to try harder.";
			mes "Anyways.. Thanks for listening.";
			break;

		case 3:
			cutin "job_bard_aiolo02",2;
			mes "[Lalo]";
			mes "Oy, not requesting a song when you run into a Bard isn't very polite.";
			mes "Well... can't help it since you look like you're in a hurry anyways.";
			next;
			mes "[Lalo]";
			mes "Hunting is good... but you can't forget to relax once in a while.";
			mes "Youth is short and won't come again once it passes by..";
			break;
		}
		close2;
		cutin "job_bard_aiolo02",255;
		end;
	}
	else if(BARD_Q == 1) {
		cutin "job_bard_aiolo01",2;
		mes "[Lalo]";
		mes "Hey there Archer fellow.";
		mes "How can a wanderer like me help you?";
		next;
		switch(select("You have a nice voice.", "Could you sing for me, please?", "Nothing.")) {
		case 1:
			mes "[Lalo]";
			mes "Hoho, your voice is rather nice as well?";
			mes "Ever think about singing?";
			next;
			if (select("Of course!", "I can't quite possibly...") == 1) {
				mes "[Lalo]";
				mes "Haha, nice attitude. You have to be like that to become a Bard.";
				mes "I'll help you become a Bard then.";
				next;
				mes "[Lalo]";
				mes "But before that... do you think you can bring me a Flower?";
				mes "I need to smell the scent of a Flower to feel like teaching.";
				next;
				mes "[Lalo]";
				mes "It doesn't really matter which Flower, but try to bring one that I like.";
				mes "And don't just buy any random Flower, ok?";
				BARD_Q = 2;
				changequest 3000,3001;
				close2;
				cutin "job_bard_aiolo01",255;
				end;
			}
			mes "[Lalo]";
			mes "Haha, what a timid one.";
			mes "Don't think so little of yourself.";
			next;
			mes "[Lalo]";
			mes "You have plenty of talent.";
			mes "Come again if you change your mind.";
			break;

		case 2:
			mes "[Lalo]";
			mes "Hmm... seems like you have some singing talents?";
			mes "Don't just request songs.. singing to others is quite fun, too.";
			next;
			mes "[Lalo]";
			mes "Try enjoying your life as a Bard.";
			mes "You go from town to town, singing to the people. Doesn't it sound great?";
			break;

		case 3:
			mes "[Lalo]";
			mes "Hmm... I'm not sure what's what, but enjoy life.";
			mes "You look too uptight.";
			next;
			mes "[Lalo]";
			mes "Well then~ Have a great time~";
			break;
		}
		close2;
		cutin "job_bard_aiolo01",255;
		end;
	}
	else if(BARD_Q == 2) {
		cutin "job_bard_aiolo01",2;
		mes "[Lalo]";
		mes "Welcome! Archer friend.";
		mes "Did you bring a Flower? Let me see.";
		next;
		mes "[Lalo]";
		//Good Flowers
		if (countitem(Singing_Flower) > 0) {
			mes "Ooh! It's a Singing Flower!";
			mes "It's full of my memories...";
			next;
			delitem Singing_Flower,1; //Singing Flower
			mes "[Lalo]";
			mes "My friend Tchaikovsky used to like it.";
			mes "I wonder what he's doing now...";
		}
		else if(countitem(Hinalle) > 0) {
			mes "Aah... the cute Hinelle...";
			mes "It doesn't have a scent but it's a very moderate cute flower.";
			next;
			delitem Hinalle,1;
			mes "[Lalo]";
			mes "The leaves gave me strength when I used to fall.";
			mes "I really like this flower, thank you.";
		}
		else if(countitem(Aloe) > 0) {
			mes "Aloe... This is a rare flower.";
			mes "How'd you get it? Rather skilled, eh?";
			next;
			delitem Aloe,1;
			mes "[Lalo]";
			mes "The leaves are good and Aloe Vera is delicious, too..";
			mes "but it's defnitely the most beautiful when it's a flower.";
		}
		else if(countitem(Ment) > 0) {
			mes "Ment... You can forget about all your hardships with one of these.";
			mes "Nice to see it in such a long time!";
			next;
			delitem Ment,1;
			mes "[Lalo]";
			mes "I heard you can make Anodyne with it...";
			mes "But that would be a slight waste.. thanks!";
		}
		else if(countitem(Izidor) > 0) {
			mes "Ooh, isn't this an Izidor?";
			mes "It's a dangerous yet beautiful flower...";
			next;
			delitem Izidor,1;
			mes "[Lalo]";
			mes "The deep purple charms a person.. ";
			mes "Thank you, I really like this flower.";
		}
		else if(countitem(Witherless_Rose) > 0) {
			mes "Ooh, a Witherless Rose. The strong flower that doesn't wither.";
			mes "Great to give to a girlfriend.";
			next;
			delitem Witherless_Rose,1;
			mes "[Lalo]";
			mes "I wonder if it would be ok for a wanderer like me to accept it.";
			mes "Haha, it should be ok.. right?";
		}
		else if(countitem(Frozen_Rose) > 0 ) {
			mes "Frozen Rose... you can't really call this a flower,";
			mes "But it is still beautiful... a clear Rose.";
			next;
			delitem Frozen_Rose,1;
			mes "[Lalo]";
			mes "You can call it a flower even though it doesn't have a scent anymore.";
			mes "Then I'll greatly take this.";
		}
		else if(countitem(Illusion_Flower) > 0) {
			mes "Oh, isn't this an Illusion Flower!?";
			mes "Wow, how did you obtain such a rare flower!!";
			next;
			delitem Illusion_Flower,1;
			mes "[Lalo]";
			mes "Than you very much, aah... I feel like heaven is in front of my eyes.";
			mes "What a wonderful feeling! I'm really happy!";
		}
		//Bad Flowers
		else if(countitem(Flower) > 0) {
			cutin "job_bard_aiolo02",2;
			mes "Eh? This is just a normal flower.";
			mes "I like it... but it's not enough.";
			next;
			mes "[Lalo]";
			mes "You can get this flower from the girl in Prontera.";
			mes "Please bring me a different flower.";
			close2;
			cutin "job_bard_aiolo02",255;
			end;
		}
		else if(countitem(Bunch_Of_Flowers) > 0) {
			mes "Oh no, you brought a Bouquet?";
			mes "You can't bring me something like this.";
			next;
			mes "[Lalo]";
			mes "Go give this to a graduating Sage or something.";
			mes "Since it's great as that kind of gift... Bring a different flower.";
			close2;
			cutin "job_bard_aiolo01",255;
			end;
		}
		else if(countitem(Wedding_Bouquet) > 0) {
			cutin "job_bard_aiolo02",2;
			mes "Oy oy... did you go to a wedding or something?";
			mes "What do you expect a guy to do with a Wedding Bouquet?";
			next;
			mes "[Lalo]";
			mes "It's not me. Go give it to a lady or something.";
			mes "This isn't the type of flower I wanted.";
			close2;
			cutin "job_bard_aiolo02",255;
			end;
		}
		else if(countitem(Fancy_Flower) > 0) {
			mes "Mmm... a Fancy Flower.";
			mes "It's nice... but this isn't good enough.";
			next;
			mes "[Lalo]";
			mes "I like flowers that have a scent and are beautiful.";
			mes "I don't like fake flowers that go on top of heads.";
			close2;
			cutin "job_bard_aiolo01",255;
			end;
		}
		else if(countitem(Blossom_Of_Maneater) > 0) {
			cutin "job_bard_aiolo02",2;
			mes "...Agh, why'd you bring such a hideous thing?";
			mes "Are you thinking at all?";
			next;
			mes "[Lalo]";
			mes "if you were trying to be funny, it was a good attempt...";
			mes "but bring a normal flower now.";
			close2;
			cutin "job_bard_aiolo02",255;
			end;
		}
		else {
			cutin "job_bard_aiolo02",2;
			mes "Hmm? What... you didnt' bring anything.";
			mes "Didn't I ask you to bring a flower?";
			next;
			mes "[Lalo]";
			mes "Well... if you want to learn on your own, then so be it.";
			mes "Anyone can just go out and sing.";
			close2;
			cutin "job_bard_aiolo02",255;
			end;
		}
		next;
		cutin "job_bard_aiolo01",2;
		mes "[Lalo]";
		mes "As I promised, I'll help you become a Bard.";
		mes "But it's not easy my friend. Haha!";
		next;
		mes "[Lalo]";
		mes "It is important to get to know a lot of people to learn how to sing.";
		mes "You must also keep up with all the things going on in different villages...";
		next;
		mes "[Lalo]";
		mes "There's a talking snowman in a town called Lutie.";
		mes "Go there and bring back a present.";
		next;
		BARD_Q = 3;
		changequest 3001,3002;
		xmas_npc = 1;
		mes "[Lalo]";
		mes "if you become friends with ^008800Jack Frost^000000, you will receive something.";
		mes "And also talk to the townspeople while you're at it...";
		close2;
		cutin "job_bard_aiolo01",255;
		end;
	}
	else if ((BARD_Q >= 3) || (BARD_Q <= 5)) {
		if (BARD_Q == 3) {
			if(xmas_npc > 10) { //this var is set in lutie.txt
				cutin "job_bard_aiolo01",2;
				mes "[Lalo]";
				mes "How was the trip? Did you meet a lot of people?";
				mes "You should have been able to learn something more important than a gift.";
				next;
				mes "[Lalo]";
				mes "Then, do you want to try singing...?";
				mes "I'll sing a short melody...";
				mes "and you try after.";
				if (!questprogress(3003)) {
					changequest 3002,3003;
				}
				next;
				mes "[Lalo]";
				mes "Here I go.";
				mes "Ehem *clears throat*";
				mes "1, 2, 3, 4";
				next;
			}
			else {
				cutin "job_bard_aiolo01",2;
				xmas_npc = 1;
				mes "[Lalo]";
				mes "Eh, you still haven't become his friend?";
				mes "Talking will not be enough.";
				next;
				mes "[Lalo]";
				mes "if you become friends with ^008800Jack Frost^000000, you will receive something.";
				mes "And talk with the village people, too...";
				close2;
				cutin "job_bard_aiolo01",255;
				end;
			}
		}
		else if (BARD_Q == 4) {
			cutin "job_bard_aiolo01",2;
			mes "[Lalo]";
			mes "Hmm... this time you can do better, right?";
			mes "Let's try again, you can do it.";
			next;
			mes "[Lalo]";
			mes "I'll sing one part...";
			mes "and you try it after.";
			next;
			mes "[Lalo]";
			mes "Here we go.";
			mes "*Ehem*";
			mes "1, 2, 3, 4";
			next;
		}
		if (BARD_Q != 5) {
			.@bard_s = rand(1,5);
			if (.@bard_s == 1) {
				mes "^3377FFThere was a man^000000";
				mes "who was said to be immortal.";
				mes "His name Jichfreid,";
				mes "Son of the hero Jichmunt.";
				mes "The evil giant Papner,";
				mes "Turned into a dragon and ate him.";
				next;
				input .@Song$;
				if (.@Song$ != "There was a man")
					.@w_point += 1;

				mes "^3377FFThere was a man";
				mes "who was said to be immortal.^000000";
				mes "His name Jichfreid,";
				mes "Son of the hero Jichmunt.";
				mes "The evil giant Papner,";
				mes "Turned into a dragon and ate him.";
				next;
				input .@Song$;
				if (.@Song$ != "who was said to be immortal.")
					.@w_point += 1;

				mes "^3377FFThere was a man";
				mes "who was said to be immortal.";
				mes "His name Jichfreid,^000000";
				mes "Son of the hero Jichmunt.";
				mes "The evil giant Papner,";
				mes "Turned into a dragon and ate him.";
				next;
				input .@Song$;
				if (.@Song$ != "His name Jichfreid,")
					.@w_point += 1;

				mes "^3377FFThere was a man";
				mes "who was said to be immortal.";
				mes "His name Jichfreid,";
				mes "Son of the hero Jichmunt.^000000";
				mes "The evil giant Papner,";
				mes "Turned into a dragon and ate him.";
				next;
				input .@Song$;
				if (.@Song$ != "Son of the hero Jichmunt.")
					.@w_point += 1;

				mes "^3377FFThere was a man";
				mes "who was said to be immortal.";
				mes "His name Jichfreid,";
				mes "Son of the hero Jichmunt.";
				mes "The evil giant Papner,^000000";
				mes "Turned into a dragon and ate him.";
				next;
				input .@Song$;
				if (.@Song$ != "The evil giant Papner,")
					.@w_point += 1;

				mes "^3377FFThere was a man";
				mes "who was said to be immortal.";
				mes "His name Jichfreid,";
				mes "Son of the hero Jichmunt.";
				mes "The evil giant Papner,";
				mes "Turned into a dragon and ate him.^000000";
				next;
				input .@Song$;
				if (.@Song$ != "Turned into a dragon and ate him.")
					.@w_point += 1;
			}
			else if (.@bard_s == 2) {
				mes "^3377FFA Merchant without money or equipment,^000000";
				mes "a Merchant that couldn't sell anything.";
				mes "But he was too proud to beg.";
				mes "So he gathered some money selling items.";
				mes "At first he only sold Red Potions.";
				mes "Some say he sold Sweet Potatoes, too.";
				next;
				input .@Song$;
				if (.@Song$ != "A Merchant without money or equipment,")
					.@w_point += 1;

				mes "^3377FFA Merchant without money or equipment,";
				mes "a Merchant that couldn't sell anything.^000000";
				mes "But he was too proud to beg.";
				mes "So he gathered some money selling items.";
				mes "At first he only sold Red Potions.";
				mes "Some say he sold Sweet Potatoes, too.";
				next;
				input .@Song$;
				if (.@Song$ != "a Merchant that couldn't sell anything.")
					.@w_point += 1;

				mes "^3377FFA Merchant without money or equipment,";
				mes "a Merchant that couldn't sell anything.";
				mes "But he was too proud to beg.^000000";
				mes "So he gathered some money selling items.";
				mes "At first he only sold Red Potions.";
				mes "Some say he sold Sweet Potatoes, too.";
				next;
				input .@Song$;
				if (.@Song$ != "But he was too proud to beg.")
					.@w_point += 1;

				mes "^3377FFA Merchant without money or equipment,";
				mes "a Merchant that couldn't sell anything.";
				mes "But he was too proud to beg.";
				mes "So he gathered some money selling items.^000000";
				mes "At first he only sold Red Potions.";
				mes "Some say he sold Sweet Potatoes, too.";
				next;
				input .@Song$;
				if (.@Song$ != "So he gathered some money selling items.")
					.@w_point += 1;

				mes "^3377FFA Merchant without money or equipment,";
				mes "a Merchant that couldn't sell anything.";
				mes "But he was too proud to beg.";
				mes "So he gathered some money selling items.";
				mes "At first he only sold Red Potions.^000000";
				mes "Some say he sold Sweet Potatoes, too.";
				next;
				input .@Song$;
				if (.@Song$ != "At first he only sold Red Potions.")
					.@w_point += 1;

				mes "^3377FFA Merchant without money or equipment,";
				mes "a Merchant that couldn't sell anything.";
				mes "But he was too proud to beg.";
				mes "So he gathered some money selling items.";
				mes "At first he only sold Red Potions.";
				mes "Some say he sold Sweet Potatoes, too.^000000";
				next;
				input .@Song$;
				if (.@Song$ != "Some say he sold Sweet Potatoes, too.")
					.@w_point += 1;
			}
			else if (.@bard_s == 3) {
				mes "^3377FFAll Gods never age.^000000";
				mes "The ever so Beautiful Goddess Eden,";
				mes "Beautiful and graceful Goddess Eden,";
				mes "Odin's daughter-in-law and Bragi's wife.";
				mes "Her sweet apples in her basket,";
				mes "All thanks to her sweet apples.";
				next;
				input .@Song$;
				if (.@Song$ != "All Gods never age.")
					.@w_point += 1;

				mes "^3377FFAll Gods never age.";
				mes "The ever so Beautiful Goddess Eden,^000000";
				mes "Beautiful and graceful Goddess Eden,";
				mes "Odin's daughter-in-law and Bragi's wife.";
				mes "Her sweet apples in her basket,";
				mes "All thanks to her sweet apples.";
				next;
				input .@Song$;
				if (.@Song$ != "The ever so Beautiful Goddess Eden,")
					.@w_point += 1;

				mes "^3377FFAll Gods never age.";
				mes "The ever so Beautiful Goddess Eden,";
				mes "Beautiful and graceful Goddess Eden,^000000";
				mes "Odin's daughter-in-law and Bragi's wife.";
				mes "Her sweet apples in her basket,";
				mes "All thanks to her sweet apples.";
				next;
				input .@Song$;
				if (.@Song$ != "Beautiful and graceful Goddess Eden,")
					.@w_point += 1;

				mes "^3377FFAll Gods never age.";
				mes "The ever so Beautiful Goddess Eden,";
				mes "Beautiful and graceful Goddess Eden,";
				mes "Odin's daughter-in-law and Bragi's wife.^000000";
				mes "Her sweet apples in her basket,";
				mes "All thanks to her sweet apples.";
				next;
				input .@Song$;
				if (.@Song$ != "Odin's daughter-in-law and Bragi's wife.")
					.@w_point += 1;

				mes "^3377FFAll Gods never age.";
				mes "The ever so Beautiful Goddess Eden,";
				mes "Beautiful and graceful Goddess Eden,";
				mes "Odin's daughter-in-law and Bragi's wife.";
				mes "Her sweet apples in her basket,^000000";
				mes "All thanks to her sweet apples.";
				next;
				input .@Song$;
				if (.@Song$ != "Her sweet apples in her basket,")
					.@w_point += 1;

				mes "^3377FFAll Gods never age.";
				mes "The ever so Beautiful Goddess Eden,";
				mes "Beautiful and graceful Goddess Eden,";
				mes "Odin's daughter-in-law and Bragi's wife.";
				mes "Her sweet apples in her basket,";
				mes "All thanks to her sweet apples.^000000";
				next;
				input .@Song$;
				if (.@Song$ != "All thanks to her sweet apples.")
					.@w_point += 1;
			}
			else if (.@bard_s == 4) {
				mes "^3377FFBragi, Bragi,^000000";
				mes "Forever call the poets name.";
				mes "My songs are his breath,";
				mes "My mind is his will,";
				mes "All wandering poets are his people,";
				mes "And all praise shall go to him.";
				next;
				input .@Song$;
				if (.@Song$ != "Bragi, Bragi,")
					.@w_point += 1;

				mes "^3377FFBragi, Bragi,";
				mes "Forever call the poets name.^000000";
				mes "My songs are his breath,";
				mes "My mind is his will,";
				mes "All wandering poets are his people,";
				mes "And all praise shall go to him.";
				next;
				input .@Song$;
				if (.@Song$ != "Forever call the poets name.")
					.@w_point += 1;

				mes "^3377FFBragi, Bragi,";
				mes "Forever call the poets name.";
				mes "My songs are his breath,^000000";
				mes "My mind is his will,";
				mes "All wandering poets are his people,";
				mes "And all praise shall go to him.";
				next;
				input .@Song$;
				if (.@Song$ != "My songs are his breath,")
					.@w_point += 1;

				mes "^3377FFBragi, Bragi,";
				mes "Forever call the poets name.";
				mes "My songs are his breath,";
				mes "My mind is his will,^000000";
				mes "All wandering poets are his people,";
				mes "And all praise shall go to him.";
				next;
				input .@Song$;
				if (.@Song$ != "My mind is his will,")
					.@w_point += 1;

				mes "^3377FFBragi, Bragi,";
				mes "Forever call the poets name.";
				mes "My songs are his breath,";
				mes "My mind is his will,";
				mes "All wandering poets are his people,^000000";
				mes "And all praise shall go to him.";
				next;
				input .@Song$;
				if (.@Song$ != "All wandering poets are his people,")
					.@w_point += 1;

				mes "^3377FFBragi, Bragi,";
				mes "Forever call the poets name.";
				mes "My songs are his breath,";
				mes "My mind is his will,";
				mes "All wandering poets are his people,";
				mes "And all praise shall go to him.^000000";
				next;
				input .@Song$;
				if (.@Song$ != "And all praise shall go to him.")
					.@w_point += 1;
			}
			else {
				mes "^3377FFLouder, louder, louder.^000000";
				mes "Give strength to the warriors!";
				mes "Shake the sky and roar through the land.";
				mes "Make my heart pound again!";
				mes "Let the castle walls ring.";
				mes "This day will never come again!";
				next;
				input .@Song$;
				if (.@Song$ != "Louder, louder, louder.")
					.@w_point += 1;

				mes "^3377FFLouder, louder, louder.";
				mes "Give strength to the warriors!^000000";
				mes "Shake the sky and roar through the land.";
				mes "Make my heart pound again!";
				mes "Let the castle walls ring.";
				mes "This day will never come again!";
				next;
				input .@Song$;
				if (.@Song$ != "Give strength to the warriors!")
					.@w_point += 1;

				mes "^3377FFLouder, louder, louder.";
				mes "Give strength to the warriors!";
				mes "Shake the sky and roar through the land.^000000";
				mes "Make my heart pound again!";
				mes "Let the castle walls ring.";
				mes "This day will never come again!";
				next;
				input .@Song$;
				if (.@Song$ != "Shake the sky and roar through the land.")
					.@w_point += 1;

				mes "^3377FFLouder, louder, louder.";
				mes "Give strength to the warriors!";
				mes "Shake the sky and roar through the land.";
				mes "Make my heart pound again!^000000";
				mes "Let the castle walls ring.";
				mes "This day will never come again!";
				next;
				input .@Song$;
				if (.@Song$ != "Make my heart pound again!")
					.@w_point += 1;

				mes "^3377FFLouder, louder, louder.";
				mes "Give strength to the warriors!";
				mes "Shake the sky and roar through the land.";
				mes "Make my heart pound again!";
				mes "Let the castle walls ring.^000000";
				mes "This day will never come again!";
				next;
				input .@Song$;
				if (.@Song$ != "Let the castle walls ring.")
					.@w_point += 1;

				mes "^3377FFLouder, louder, louder.";
				mes "Give strength to the warriors!";
				mes "Shake the sky and roar through the land.";
				mes "Make my heart pound again!";
				mes "Let the castle walls ring.";
				mes "This day will never come again!^000000";
				next;
				input .@Song$;
				if (.@Song$ != "This day will never come again!")
					.@w_point += 1;
			}

			if (.@w_point) {
				cutin "job_bard_aiolo02",2;
				mes "[Lalo]";
				mes "Oy, You got the lyrics wrong!";
				mes "Can't you even sing along..?";
				next;
				mes "[Lalo]";
				mes "Your pronunciation is very unclear.";
				mes "Do a better job next time.";
				close2;
				cutin "job_bard_aiolo02",255;
				end;
			}
			mes "[Lalo]";
			mes "..........";
			next;
			BARD_Q = 5;
			mes "[Lalo]";
			mes "Wonderful! Finished it in one try!";
			mes "You can become a great Bard. ";
			next;
			mes "[Lalo]";
			mes "Mmm... So you will not become a Bard.";
			mes "But I want to give you a souvenir...";
			next;
			mes "[Lalo]";
			mes "Do you want to just change jobs now?";
			mes "Or do you want a present.";
			next;
			.@selection = select("Just change my job please.", "I'd be thankful for a present.");
		}
		if ((.@selection == 1) || (BARD_Q == 5)) {
			if(SkillPoint) {
				cutin "job_bard_aiolo01",2;
				mes "[Lalo]";
				mes "Ah... Everything is good, but you still have some skill points left.";
				mes "Go learn the rest of the skills and come back.";
				next;
				mes "[Lalo]";
				mes "And I am going to give you a small present...";
				mes "So bring some trunks.";
				mes "It doesn't matter what kind, as long as they are 60 of the same kind...";
				close2;
				cutin "job_bard_aiolo01",255;
				end;
			}
			else {
				switch(BARD_Q) {
				case 5:
					if(countitem(Wooden_Block) > 59) callsub S_ChangeJob,1019,1901;
					else if(countitem(Tree_Of_Archer_3) > 59) callsub S_ChangeJob,1068,1903;
					else if(countitem(Tree_Of_Archer_2) > 59) callsub S_ChangeJob,1067,1903;
					else if(countitem(Tree_Of_Archer_1) > 59) {
						if(JobLevel > 49) callsub S_ChangeJob,1066,1910;
						else callsub S_ChangeJob,1066,1905;
					}
					cutin "job_bard_aiolo01",2;
					mes "[Lalo]";
					mes "Mmm? Seems like you haven't prepared all trunks the yet? ";
					mes "Do you want to just change jobs anyways?";
					next;
					if (select("Yes, just change my job already.", "No, I'll go prepare them.") == 2)
						break;
				default:
					completequest 3003;
					callfunc "Job_Change",Job_Bard;
					callfunc "F_ClearJobVar";		//clears all job variables for the current player
					mes "[Lalo]";
					mes "Very well! Hope you sing happy enjoyable songs.";
					mes "Live like the wind and the clouds!";
					next;
					mes "[Lalo]";
					mes "See you again next time!";
					close2;
					cutin "job_bard_aiolo01",255;
					end;
				}
			}
		}
		changequest 3003,3004;
		mes "[Lalo]";
		mes "Hmm... very well, bring some trunks.";
		mes "It doesn't matter what kind, as long as they are 60 of the same kind...";
		next;
		mes "[Lalo]";
		mes "I will give you a gift once you bring them.";
		mes "Have a safe trip.";
		close2;
		cutin "job_bard_aiolo01",255;
		end;
	}
	cutin "job_bard_aiolo01",2;
	mes "[Lalo]";
	mes "Whee~ whee~ whee~";
	close2;
	cutin "job_bard_aiolo01",255;
	end;

S_ChangeJob:
	completequest 3004;
	callfunc "Job_Change",Job_Bard;
	callfunc "F_ClearJobVar";
	mes "[Lalo]";
	mes "Good job. I will make you a job change souvenir with this.";
	mes "Wait just a moment.";
	next;
	mes "[Lalo]";
	mes "^3355FFScrape Scrape Tang Tang^000000";
	mes "^3355FFSqueak Squeak Scratch Scratch^000000";
	delitem getarg(0),60;
	getitem getarg(1),1;
	next;
	mes "[Lalo]";
	mes "Here you go, a souvenir. It is useful when you sing.";
	mes "Hope you sing happy songs.";
	next;
	mes "[Lalo]";
	mes "See you next time!";
	close2;
	cutin "job_bard_aiolo01",255;
	end;
}
