//================= Hercules Script =======================================
//=       _   _                     _
//=      | | | |                   | |
//=      | |_| | ___ _ __ ___ _   _| | ___  ___
//=      |  _  |/ _ \ '__/ __| | | | |/ _ \/ __|
//=      | | | |  __/ | | (__| |_| | |  __/\__ \
//=      \_| |_/\___|_|  \___|\__,_|_|\___||___/
//================= License ===============================================
//= This file is part of Hercules.
//= http://herc.ws - http://github.com/HerculesWS/Hercules
//=
//= Copyright (C) 2012-2015  Hercules Dev Team
//= Copyright (C)  rAthena Dev Team
//= Copyright (C)  Euphy
//= Copyright (C)  eAthena Dev Team
//= Copyright (C)  L0ne_W0lf
//= Copyright (C)  Lupus
//=
//= Hercules is free software: you can redistribute it and/or modify
//= it under the terms of the GNU General Public License as published by
//= the Free Software Foundation, either version 3 of the License, or
//= (at your option) any later version.
//=
//= This program is distributed in the hope that it will be useful,
//= but WITHOUT ANY WARRANTY; without even the implied warranty of
//= MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//= GNU General Public License for more details.
//=
//= You should have received a copy of the GNU General Public License
//= along with this program.  If not, see <http://www.gnu.org/licenses/>.
//=========================================================================
//= Bunny Band Quest
//================= Description ===========================================
//= Quest to obtain a Bunny Band headgear.
//================= Current Version =======================================
//= 1.6
//=========================================================================

alberta,26,229,0	script	Kafra Employee#bunny	4_M_01,{
	if (BUNYBND == 1) {
		mes "[Kafra Employee]";
		mes "Hello there~!";
		mes "How'd you like to";
		mes "participate in Kafra";
		mes "Corporation's special";
		mes "^529DFFBunny Band Event^000000?";
		next;
		switch(select("Sure, I brought the items.", "Event Information", "Cancel")) {
		case 1:
			mes "[Kafra Employee]";
			mes "Alrighty~";
			mes "Let me check to";
			mes "see if you brought";
			mes "all the items...";
			next;
			setarray .@items[0],949,100,706,1,722,1,2213,1;
			for(.@i = 0; .@i<8; .@i += 2)
				if (countitem(.@items[.@i]) < .@items[.@i+1]) {
					mes "[Kafra Employee]";
					mes "Ooh, I'm sorry";
					mes "but you need to";
					mes "bring at least";
					mes .@items[.@i+1]+" "+getitemname(.@items[.@i])+((!.@i)?"s.":".");
					close;
				}
			mes "[Kafra Employee]";
			mes "Great, I see that";
			mes "you've gathered";
			mes "everything I need to";
			mes "make the Bunny Band.";
			mes "Please wait a moment";
			mes "while I put it together...";
			next;
			for(.@i = 0; .@i<8; .@i += 2)
				if (countitem(.@items[.@i]) < .@items[.@i+1]) {
					mes "[Kafra Employee]";
					mes "Hm? I'm sorry,";
					mes "but I actually can't";
					mes "make this right now. You";
					mes "need "+.@items[.@i+1]+" "+getitemname(.@items[.@i])+((!.@i)?"s":"");
					mes "in order for me to put this";
					mes "Bunny Band together...";
					close;
				}
			delitem Feather,100;
			delitem Four_Leaf_Clover,1;
			delitem Scarlet_Jewel,1;
			delitem Cat_Hairband,1;
			mes "[Kafra Employee]";
			mes "Ah, here you go~";
			mes "The perfect Bunny Band!";
			mes "Well, I hope you enjoy it.";
			getitem Bunny_Band,1;
			BUNYBND = 0;
			next;
			mes "[Kafra Employee]";
			mes "Thank you for";
			mes "participating in this";
			mes "special event and your";
			mes "continued patronage";
			mes "of the Kafra Services~";
			close;
		case 2:
			break;
		case 3:
			close;
		}
	} else {
		mes "[Kafra Employee]";
		mes "Hi there~! Would you like";
		mes "to join our special ^529DFFBunny";
		mes "Band Event^000000 hosted by the Kafra";
		mes "Corporation and sponsored by";
		mes "the Alberta Merchant Guild?";
		next;
		switch(select("Join the Event", "Event Information", "Cancel")) {
		case 1:
			BUNYBND = 1;
			mes "[Kafra Employee]";
			mes "Great! Thanks for";
			mes "participating! If you";
			mes "haven't already heard,";
			mes "you need to collect these";
			mes "items if you want me put a";
			mes "Bunny Band together for you...";
			next;
			mes "[Kafra Employee]";
			mes "100 Feathers,";
			mes "1 Four-Leaf Clover,";
			mes "1 Kitty Band and";
			mes "1 Pearl. That's it!";
			mes "Good luck and I'll be";
			mes "waiting for you here~";
			close;
		case 2:
			break;
		case 3:
			close;
		}
	}
	mes "[Kafra Employee]";
	mes "To thank our valued";
	mes "customers, Kafra Corporation";
	mes "has prepared a special event";
	mes "where Kafra Employee will assemble";
	mes "Bunny Bands for adventurers";
	mes "who bring the required items.";
	next;
	mes "[Kafra Employee]";
	mes "For this special,";
	mes "one of a kind item,";
	mes "bring 100 Feathers,";
	mes "1 Four-Leaf Clover,";
	mes "1 Kitty Band and";
	mes "1 Pearl.";
	next;
	mes "[Kafra Employee]";
	mes "When you're ready,";
	mes "come back and bring";
	mes "those items to me.";
	mes "(Sponsored by the";
	mes "Alberta Merchant Guild).";
	close;
}
