//===== rAthena Script =======================================
//= Euphy's WOE Controller
//===== By: ==================================================
//= Euphy
//===== Current Version: =====================================
//= 1.5
//===== Compatible With: =====================================
//= rAthena Project
//===== Description: =========================================
//= A controller for War of Emperium designed for
//= simplicity and ease of use.
//= Many concepts taken from ToastOfDoom's script,
//= and "rewards" function originally by Goddameit.
//===== Additional Comments: =================================
//= Be sure to disable the default agit controllers!
//== npc\guild\agit_controller.txt
//== npc\guild2\agit_start_se.txt
//============================================================

// Information NPC
//============================================================
prontera,149,193,4	script	WOE Information	4_M_YATTWARP,{
	doevent "WOE_CONTROL::OnMenu";
	end;
OnAgitStart:
	while(agitcheck()) {
		specialeffect EF_PNEUMA;
		sleep 9000;
	}
	end;
}

// Script Core
//============================================================
-	script	WOE_CONTROL	-1,{
function Disp_Owner; function Add_Zero;


OnInit:

// -----------------------------------------------------------
//  Configuration settings.
// -----------------------------------------------------------

// Shop

	// sHOP Settings	
	tradertype(NST_CUSTOM);
	sellitem 13621,15;
	sellitem 13505,100;
	sellitem 12310,5;
	sellitem 5807,50;
	sellitem 13778,100;
	sellitem 13668,20;
	sellitem 13658,20;
	sellitem 13536,5;
	sellitem 13537,5;
	sellitem 14003,3;
	sellitem 5419,50;
	sellitem 12211,5;	

// WoE Reward
	.min_time = 30; // Minimum time in minutes to claim the reward.
	setarray .points$[0],"#WOETIME","WoE Points"; // Point variable and human-friendly text
	.point = 10; // Points that will be given
	.zeny = 0; // Zeny that will be given
	// Items that will be given
	setarray .items,14003,5;
	.idle_tolerance = 5; // Minutes of idling before the timer becomes be paused.

// Core
	set .CastleWarp,1;		// 1: Always enable all castle warps. | 0: Warp only to active castles.
	set .AutoKick,1;		// Automatically kick players from inactive castles during WOE? (1:yes / 0:no)
	set .NoOwner,1; 		// Automatically kick players from unconquered castles outside of WOE? (1:yes / 0:no)
	set .ExitWarp,0;		// Warp all players from castles when WOE ends? (1:yes / 0:no)
	set .GMAccess,99;		// GM level required to access Session Manager.

// -----------------------------------------------------------
//  Reward options.
// -----------------------------------------------------------
//  [1] Enable rewards.
//  [2] Mail all rewards.
//      - If not set, players receive items in their inventory.
//      - Only ONE item can be sent via mail, plus Zeny.
//      - Note that offline players do NOT receive rewards.
//  [4] Only reward Guild Masters.
//      - If not set, all guild members are rewarded.
//      - If mailing is enabled (option 2), offline Guild Masters WILL receive rewards.
//  [8] Duplicate IP check.
//      - Members in a guild with the same IP address are not rewarded.
//      - If Guild Masters is enabled (option 4), this feature is not used.
// -----------------------------------------------------------


	// Combine values as needed (e.g. 1|8 = 1+8 = 9).
	set .Options, 0;

	// Rewards per castle.
	// -- when given directly: <itemID>,<amount>{,<itemID>,<amount>,...}
	// -- via mail (option 2): <itemID>,<amount>,<Zeny>
	setarray .Reward[0],14003,5;

// -----------------------------------------------------------
//  Constants (leave this section alone).
// -----------------------------------------------------------

	setarray $@Castles$[0],
		"prtg_cas01","prtg_cas02","prtg_cas03","prtg_cas04","prtg_cas05",
		"payg_cas01","payg_cas02","payg_cas03","payg_cas04","payg_cas05",
		"gefg_cas01","gefg_cas02","gefg_cas03","gefg_cas04","gefg_cas05",
		"aldeg_cas01","aldeg_cas02","aldeg_cas03","aldeg_cas04","aldeg_cas05",
		"arug_cas01","arug_cas02","arug_cas03","arug_cas04","arug_cas05",
		"schg_cas01","schg_cas02","schg_cas03","schg_cas04","schg_cas05";
	setarray .EndLabel$[0],"ar01","ar02","ar03","ar04","ar05","sc01","sc02","sc03","sc04","sc05";
	setarray .Days$[0],"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday";
	setarray .Regions$[0],"Prontera","Payon","Geffen","Aldebaran","Arunafeltz","Schwaltzvalt";
	setarray .Map$[0],"prt_gld","pay_gld","gef_fild13","alde_gld","aru_gld","sch_gld";
	setarray .MapX[0],134,240,153,111,208,121,295,317,140,204,214,308,143,193,305,48, 95,142,239,264,158,83, 68,299,292,293,288, 97,137, 71;
	setarray .MapY[0], 65,128,137,240,240,233,116,293,160,266, 75,240,240,278, 87,83,249, 85,242, 90,272,47,155,345,107,100,252,196, 90,315;

// -----------------------------------------------------------

	set .Size, getarraysize($WOE_CONTROL);
	if (.AutoKick || .NoOwner)
		for(set .@i,0; .@i<30; set .@i,.@i+1) {
			setmapflag $@Castles$[.@i], mf_loadevent;
			setd "."+$@Castles$[.@i], .@i;
		}
	if (!agitcheck() && !agitcheck2()) sleep 4000;
	set .Init,1;

OnMinute00:
	freeloop(1);
	if (agitcheck() || agitcheck2()) {
		for(set .@i,0; .@i<.Size; set .@i,.@i+4)
			if (gettime(GETTIME_WEEKDAY) == $WOE_CONTROL[.@i] && gettime(GETTIME_HOUR) == $WOE_CONTROL[.@i+2]) {
			OnWOEEnd:
				announce "The War Of Emperium is over!",bc_all|bc_woe;
				agitend; agitend2;
				sleep 1000;
				for(set .@j,0; .@j<30; set .@j,.@j+1) {
					if ($@euphwoe_active[0]&(1<<.@j)) Disp_Owner($@Castles$[.@j],1);
					if (.ExitWarp) maprespawnguildid $@Castles$[.@j],0,3;
				}
				if ((.Options&1) && $@euphwoe_active[0] && .ForceEnd != 2) callsub OnReward, $@euphwoe_active[0];
				deletearray $@euphwoe_active[0],2;
				if (.ForceEnd) { set .ForceEnd,0; end; }
				break;
			}
	}
	if ((!agitcheck() && !agitcheck2()) || .Init) {
		if (!agitcheck() && !agitcheck2()) set .Init,0;
		for(set .@i,0; .@i<.Size; set .@i,.@i+4)
			if (gettime(GETTIME_WEEKDAY) == $WOE_CONTROL[.@i] && gettime(GETTIME_HOUR) >= $WOE_CONTROL[.@i+1] && gettime(GETTIME_HOUR) < $WOE_CONTROL[.@i+2]) {
				deletearray $@euphwoe_active[0],2;
				set $@euphwoe_active[0], $WOE_CONTROL[.@i+3];
				if (.Init) { agitend; agitend2; }
				else announce "The War Of Emperium has begun!",bc_all|bc_woe;
				sleep 1000;
				agitstart; agitstart2;
				$@agit_time = atoi("" + gettime(GETTIME_YEAR) + gettime(GETTIME_MONTH) + gettime(GETTIME_DAYOFMONTH) + gettime(GETTIME_HOUR));
				for(set .@j,0; .@j<30; set .@j,.@j+1) {
					if ($@euphwoe_active[0]&(1<<.@j)) {
						if (!.Init) Disp_Owner($@Castles$[.@j],0);
						set $@euphwoe_active[1], $@euphwoe_active[1] | (1<<((.@j/5)+1));
					} else {
						if (.@j<20) {
							donpcevent "Agit#"+$@Castles$[.@j]+"::OnAgitEnd";
							killmonster $@Castles$[.@j], "Agit#"+$@Castles$[.@j]+"::OnAgitBreak";
						} else {
							donpcevent "Manager#"+$@Castles$[.@j]+"::OnAgitEnd2";
							killmonster $@Castles$[.@j], "Steward#"+.EndLabel$[.@j-20]+"::OnStartArena";
						}
					}
				}
				break;
			}
	}
	set .Init,0;
	end;

function Disp_Owner {
	set .@o, getcastledata(getarg(0),1);
	if (.@o) announce "The ["+getcastlename(getarg(0))+"] castle "+((getarg(1))?"has been conquered":"is currently held")+" by the ["+getguildname(.@o)+"] guild.",bc_all|bc_woe;
	else announce "The ["+getcastlename(getarg(0))+"] castle is currently unoccupied.",bc_all|bc_woe;
	return;
}
function Add_Zero {
	return ((getarg(0)<10)?"0":"")+getarg(0)+(getarg(1,0)?".":":")+"00";
}

OnCountFunds:
	setcurrency #WOETIME;
	end;

OnPayFunds:
	#WOETIME -= @price;				
	purchaseok();
	end;

OnReward:
	set .@sql$, ((.Options&4)?"position = 0":"online = 1");
	if (.Options&2) set .@str$,gettimestr("%B %d, %Y",21);
	freeloop(1);
	for(set .@i,0; .@i<30; set .@i,.@i+1)
		if (getarg(0)&(1<<.@i)) {
			set .@gid, getcastledata($@Castles$[.@i],1);
			if (!.@gid) continue;
			set .@size, query_sql("SELECT account_id,char_id FROM `guild_member` WHERE guild_id = '"+.@gid+"' AND "+.@sql$,.@aid,.@cid);
			for(set .@j,0; .@j<.@size; set .@j,.@j+1) {
				if ((.Options&8) && !(.Options&4)) {
					set .@ip$, replacestr(getcharip(.@aid[.@j]),".","a");
					if (getd(".@ip_"+.@i+"_"+.@ip$)) continue;
					setd ".@ip_"+.@i+"_"+.@ip$,1;
				}
				if (.Options&2) {
					query_sql("INSERT INTO `mail` (send_name,dest_id,title,message,nameid,amount,identify,zeny,time) VALUES ("+
					          "'no-reply',"+.@cid[.@j]+",'** Siege Reward: "+getcastlename($@Castles$[.@i])+" **',"+
					          "'Brave one,% % Congratulations!% Your guild has successfully occupied% territory in the War of Emperium on% "+.@str$+".% % % % % [ Your reward is attached. ]',"+
					          .Reward[0]+","+.Reward[1]+",0,"+.Reward[2]+",UNIX_TIMESTAMP(NOW()))");
					if (!getd(".@str_"+.@cid[.@j]) && isloggedin(.@aid[.@j],.@cid[.@j])) {
						setd ".@str_"+.@cid[.@j],1;
						message rid2name(.@aid[.@j]),"You've got mail! Please re-login to update your mailing list.";
					}
				} else if (isloggedin(.@aid[.@j])) {
					for(set .@k,0; .@k<getarraysize(.Reward); set .@k,.@k+2)
						getitem .Reward[.@k], .Reward[.@k+1], .@aid[.@j];
					message rid2name(.@aid[.@j]),"You have been rewarded for conquering "+getcastlename($@Castles$[.@i])+".";
				}
			}
		}
	if (.Options&2) query_sql("UPDATE `mail` SET message = REPLACE(message,'%',CHAR(13)) WHERE send_name = 'no-reply'");
	return;

OnPCLoadMapEvent:
	if (!compare(strcharinfo(3),"g_cas")) end;
	if (((.AutoKick && $@euphwoe_active[0]) || (.NoOwner && !getcastledata(strcharinfo(3),1))) && !($@euphwoe_active[0]&(1<<getd("."+strcharinfo(3))))) {
		if (getcharid(2) && getcastledata(strcharinfo(3),1) == getcharid(2)) end;
		sleep2 1000;
		message strcharinfo(0), getcastlename(strcharinfo(3))+" is currently inactive.";
		sleep2 5000;
		if (compare(strcharinfo(3),"g_cas")) warp "SavePoint",0,0;
	}
	end;

OnPCLoginEvent:
	callsub(OnInitCheck);
	end;

OnInitCheck:
	callsub(OnCheck);
	addtimer 60000,strnpcinfo(0) + "::OnInitCheck";
	end;

OnCheck:
	if(!getcharid(2) || (!agitcheck() && !agitcheck2())) {
		WOE_Start = 0;
	} else {
		if(WOE_Start != $@agit_time) {
			callsub(S_OnReset);
		}
		WOE_Start = $@agit_time;
		
		getmapxy(.@map$,.@x,.@y,UNITTYPE_PC);
		if(!getmapflag(.@map$,mf_gvg)) {
			return;
		}
		if(@woe_last_map$ != .@map$) {
			@castleidx = -1;
		}
		if(@woe_last_map$ == .@map$ && @woe_last_x == .@x && @woe_last_y == .@y) {
			@woe_idle++;
		} else {
			@woe_idle = 0;
		}
		@woe_last_map$ = .@map$;
		@woe_last_x = .@x;
		@woe_last_y = .@y;
		
		if(@woe_idle < .idle_tolerance) {
			if(@castleidx == -1) {
				for(.@i = 0; .@i < getarraysize($@Castles$); ++.@i) {
					if($@Castles$[.@i] == .@map$) {
						@castleidx = .@i;
						break;
					}
				}
			}
			if(@castleidx >= 0 && $@euphwoe_active[0]&(1<<getd("."+strcharinfo(PC_MAP)))) {
				WOE_Timer++;
				dispbottom "[WOE Timer] WoE participation: " + WOE_Timer + " minutes.";
			}
		}
	}
	return;

S_OnReset:
	WOE_Timer = 0;
	WOE_Start = 0;
	WOE_Timer_Claimed = false;
	return;


OnMenu:
while(1) {
	mes "[WOE Information]";
	if (agitcheck() || agitcheck2()) {
		if ($@euphwoe_active[0]) {
			for(set .@i,0; .@i<.Size; set .@i,.@i+4)
				if (gettime(GETTIME_WEEKDAY) == $WOE_CONTROL[.@i] && gettime(GETTIME_HOUR) >= $WOE_CONTROL[.@i+1] && gettime(GETTIME_HOUR) < $WOE_CONTROL[.@i+2]) {
					set .@i, $WOE_CONTROL[.@i+2];
					break;
				}
			mes "The War of Emperium is ^0055FFactive^000000 until ^FF0000"+Add_Zero(.@i)+"^000000 in the following regions:";
			mes " ";
			for(set .@i,0; .@i<6; set .@i,.@i+1)
				if ($@euphwoe_active[1]&(1<<(.@i+1))) mes " > ^777777"+.Regions$[.@i]+"^000000";
		} else
			mes "The War of Emperium is ^0055FFactive^000000.";
	} else {
		for(set .@i,0; .@i<.Size; set .@i,.@i+4)
			if ((gettime(GETTIME_WEEKDAY) == $WOE_CONTROL[.@i] && gettime(GETTIME_HOUR) <= $WOE_CONTROL[.@i+1]) || gettime(GETTIME_WEEKDAY) < $WOE_CONTROL[.@i]) {
				setarray .@time[0],$WOE_CONTROL[.@i],$WOE_CONTROL[.@i+1];
				break;
			}
		if (!getarraysize(.@time))
			setarray .@time[0],$WOE_CONTROL[0],$WOE_CONTROL[1];
		mes "The War of Emperium is ^777777inactive^000000.";
		if (.Size) {
			mes " ";
			mes "The next session will begin";
			mes "on ^0055FF"+.Days$[.@time[0]]+"^000000 at "+Add_Zero(.@time[1])+"^000000.";
		}
	}
	next;
//	switch(select(""+((.CastleWarp || $@euphwoe_active[1])?" ~ Warp to castles...":"")+": ~ Check schedule...: ~ View castle owners...:"+((getgmlevel()<.GMAccess || !getgmlevel())?"":" ~ Manage sessions...")+": ~ ^777777Cancel^000000")) {
	switch(select(""+((.CastleWarp || $@euphwoe_active[1])?" ~ Warp to castles...":"")+": ~ Check schedule...: ~ View castle owners...:"+((getgmlevel()<.GMAccess || !getgmlevel())?"":" ~ Manage sessions...")+": ~ ^FF0000Claim Reward^000000: ~ ^FF0000WoE Shop^000000: ~ ^777777Cancel^000000")) {

	case 1:
		if (.CastleWarp) set .@clr$,"^0055FF";
		set .@menu$,"";
		for(set .@i,0; .@i<6; set .@i,.@i+1) {
			if (.CastleWarp || $@euphwoe_active[1]&(1<<(.@i+1)))
				set .@menu$, .@menu$+" ~ "+(($@euphwoe_active[1]&(1<<(.@i+1)))?.@clr$:"^777777")+.Regions$[.@i]+" Castles^000000";
			set .@menu$, .@menu$+":";
		}
		set .@i, select(.@menu$)-1;
		set .@menu$,"";
		for(set .@j,.@i*5; .@j<(.@i*5)+5; set .@j,.@j+1) {
			if (.CastleWarp || $@euphwoe_active[0]&(1<<.@j))
				set .@menu$, .@menu$+" ~ "+(($@euphwoe_active[0]&(1<<.@j))?.@clr$:"^777777")+getcastlename($@Castles$[.@j])+"^000000";
			set .@menu$, .@menu$+":";
		}
		set .@j, select(.@menu$)-1;
		warp .Map$[.@i],.MapX[(.@i*5)+.@j],.MapY[(.@i*5)+.@j];
		close;
	case 2:
		mes "[Schedule]";
		if (.Size) {
			freeloop(1);
			for(set .@i,0; .@i<.Size; set .@i,.@i+4) {
				mes "> ^FF0000"+.Days$[$WOE_CONTROL[.@i]]+" ("+Add_Zero($WOE_CONTROL[.@i+1])+"-"+Add_Zero($WOE_CONTROL[.@i+2])+")^000000";
				for(set .@j,0; .@j<30; set .@j,.@j+1)
					if ($WOE_CONTROL[.@i+3]&(1<<.@j)) mes "  ~ "+getcastlename($@Castles$[.@j])+" ^777777("+$@Castles$[.@j]+")^000000";
				if (.@i+4 < .Size) mes " ";
			}
			freeloop(0);
		} else
			mes "No times are configured.";
		next;
		break;
	case 3:
		mes "[Castle Ownership]";
		for(set .@i,0; .@i<6; set .@i,.@i+1) {
			set .@k, .@i*5;
			mes "> ^FF0000"+.Regions$[.@i]+"^000000";
			for(set .@j,.@k; .@j<(.@k+5); set .@j,.@j+1) { 
				set .@t, getcastledata($@Castles$[.@j],1);
				mes "  ~ "+getcastlename($@Castles$[.@j])+": "+((.@t)?"^0055FF"+getguildname(.@t):"^777777unoccupied")+"^000000";
			}
			if (.@i < 5) mes " ";
		}
		next;
		break;
	case 4:
	while(1) {
		mes "[Session Manager]";
		mes "There are ^0055FF"+(.Size/4)+" session(s)^000000 configured.";
		mes "What would you like to do?";
		next;
		switch(select(" ~ Add a session...: ~ Delete a session...: ~ Reload settings...:"+((agitcheck() || agitcheck2())?" ~ End WOE session...":"")+": ~ ^777777Go back^000000")) {
		case 1:
			mes "[New Session]";
			if (.Size > 127) {
				mes "You have already reached the maximum of 32 sessions.";
				next;
				break;
			}
			mes "Select a day.";
			next;
			set .@Day, select(" ~ "+implode(.Days$,": ~ "))-1;
			mes "[New Session]";
			mes "Select a start time for ^0055FF"+.Days$[.@Day]+"^000000.";
			next;
			set .@menu$,"";
			for(set .@i,0; .@i<23; set .@i,.@i+1)
				set .@menu$, .@menu$+" ~ "+Add_Zero(.@i,1)+":";
			set .@Start, select(.@menu$)-1;
			mes "[New Session]";
			mes "Select an end time for ^0055FF"+.Days$[.@Day]+"^000000.";
			next;
			set .@menu$,"";
			for(set .@i,.@Start+1; .@i<24; set.@i,.@i+1)
				set .@menu$, .@menu$+" ~ "+Add_Zero(.@i,1)+":";
			set .@End, select(.@menu$)+.@Start;
			for(set .@i,0; .@i<.Size; set .@i,.@i+4)
				if (.@Day == $WOE_CONTROL[.@i] &&
				   ((.@Start >= $WOE_CONTROL[.@i+1] && .@Start < $WOE_CONTROL[.@i+2]) ||
				    (.@End > $WOE_CONTROL[.@i+1] && .@End <= $WOE_CONTROL[.@i+2]) ||
				    (.@Start <= $WOE_CONTROL[.@i+1] && .@End >= $WOE_CONTROL[.@i+2]))) {
					mes "[New Session]";
					mes "The chosen times overlap with an existing session.";
					next;
					set .@d,1;
					break;
				}
			if (.@d) { set .@d,0; break; }
			set .@Castle,0;
			while(1) {
				mes "[New Session]";
				mes "^0055FF"+.Days$[.@Day]+" ("+Add_Zero(.@Start)+"-"+Add_Zero(.@End)+")^000000";
				mes " > Castles:";
				if (!.@Castle)
					mes "   ~ ^777777(none selected)^000000";
				else for(set .@i,0; .@i<30; set .@i,.@i+1)
					if (.@Castle&(1<<.@i)) mes "   ~ "+getcastlename($@Castles$[.@i])+" ("+$@Castles$[.@i]+")";
				next;
				set .@menu$,((.@Castle)?" ~ ^FF0000Finished...^000000":"")+":";
				for(set .@i,0; .@i<30; set .@i,.@i+1)
					set .@menu$, .@menu$+" ~ "+((.@Castle&(1<<.@i))?"^0055FF":"")+getcastlename($@Castles$[.@i])+" ("+$@Castles$[.@i]+")^000000:";
				set .@i, select(.@menu$)-1;
				if (.@i)
					set .@Castle, .@Castle^(1<<(.@i-1));
				else {
					mes "[New Session]";
					mes "Are you sure?";
					next;
					switch(select(" ~ ^0055FFAdd session...^000000: ~ Continue selecting castles...: ~ ^777777Cancel^000000")) {
					case 1:
						for(set .@i,0; .@i<.Size; set .@i,.@i+4)
							if ((.@Day == $WOE_CONTROL[.@i] && .@End <= $WOE_CONTROL[.@i+1]) || .@Day < $WOE_CONTROL[.@i]) {
								set .@d,1;
								break;
							}
						if (!.@d) { set .@d,1; set .@i,.Size; }
						copyarray $WOE_CONTROL[.@i+4], $WOE_CONTROL[.@i], .Size-.@i;
						setarray $WOE_CONTROL[.@i], .@Day, .@Start, .@End, .@Castle;
						set .Size, getarraysize($WOE_CONTROL);
					case 3:
						mes "[New Session]";
						mes ((.@d)?"Session added.":"Cancelled.");
						next;
						set .@d,1;
					case 2:
						break;
					}
					if (.@d) { set .@d,0; break; }
				}
			}
			break;
		case 2:
			mes "[Remove Session]";
			if (!.Size) {
				mes "There are no sessions configured.";
				next;
				break;
			}
			mes "Select a session to remove.";
			next;
			set .@menu$,"";
			for(set .@i,0; .@i<.Size; set .@i,.@i+4)
				set .@menu$, .@menu$+" ~ "+.Days$[$WOE_CONTROL[.@i]]+" ("+Add_Zero($WOE_CONTROL[.@i+1],1)+"-"+Add_Zero($WOE_CONTROL[.@i+2],1)+"):";
			set .@menu$, .@menu$+" ~ ^777777Cancel^000000";
			set .@i, select(.@menu$)-1;
			if (.@i == (.Size/4)) break;
			mes "[Remove Session]";
			mes "Delete ^0055FF"+.Days$[$WOE_CONTROL[.@i*4]]+"'s^000000 session?";
			mes "This action cannot be undone.";
			next;
			set .@j, select(" ~ ^FF0000Delete session...^000000: ~ ^777777Cancel^000000");
			mes "[Remove Session]";
			if (.@j == 2)
				mes "Cancelled.";
			else {
				deletearray $WOE_CONTROL[.@i*4],4;
				set .Size, getarraysize($WOE_CONTROL);
				mes "Session deleted.";
			}
			next;
			break;
		case 3:
			mes "[Reload Settings]";
			mes "This will trigger all events related to new session configurations, if any.";
			if (agitcheck() || agitcheck2()) {
				mes " ";
				mes "Be aware that this will disrupt the current WOE session.";
			}
			next;
			set .@i, select(" ~ ^0055FFReload settings...^000000: ~ ^777777Cancel^000000");
			mes "[Reload Settings]";
			if (.@i == 2) mes "Cancelled.";
			else {
				set .Init,1;
				donpcevent "WOE_CONTROL::OnMinute00";
				mes "Variables have been re-initialized.";
			}
			next;
			break;
		case 4:
			mes "[Force Agit End]";
			if (!agitcheck() && !agitcheck2())  {
				mes "WOE has already ended.";
				next;
				break;
			}
			mes "This command will safely execute all AgitEnd events.";
			mes " ";
			mes "Kill the current WOE session?";
			next;
			set .@i, select(" ~ ^FF0000End session...^000000:"+((.Options&1)?" ~ ^FF0000End session without rewards...^000000":"")+": ~ ^777777Cancel^000000");
			mes "[Force Agit End]";
			if (.@i == 3)
				mes "Cancelled.";
			else {
				set .ForceEnd, .@i;
				donpcevent "WOE_CONTROL::OnWOEEnd";
				mes "WOE session terminated.";
			}
			next;
			break;
		case 5:
			set .@d,1; break;
		}
		if (.@d) { set .@d,0; break; }
		} break;
	case 5:
		mes "[Claim Reward]";
		mes "You can claim the WoE participation prizes if you participated in the last WoE longer than ^0055FF" + .min_time + " minutes.^000000";
		mes "^FF0000Reward:^000000";
		if(.point)
			mes "^0055FF"+.point+"x^000000 "+.points$[1];
		if(.zeny)
			mes "- Zeny:" + callfunc("F_InsertComma",.zeny);
		.@sz = getarraysize(.items);
		if(.@sz) {
			for(.@i = 0; .@i < .@sz; .@i += 2) {
				mes "^0055FF"+.items[.@i+1]+"x^000000 " + getitemname(.items[.@i]);
			}
		}
		next;
		if (agitcheck() || agitcheck2()) {
			mes "[Claim Reward]";
			mes "You can only claim the prizes when the WoE is not active.";
			//mes "Your WoE participation time is "+ WOE_Timer +" minute" + (WOE_Timer > 1 ? "s" : "") + ".";
			close;
		}
		if(WOE_Timer_Claimed) {
			mes "[Claim Reward]";
			mes "You already claimed your WoE participation prize.";
			close;
		}
		if(WOE_Timer < .min_time) {
			mes "[Claim Reward]";
			mes "Your WoE participation time is not enough.";
			mes "Your WoE participation time is "+ WOE_Timer +" minute" + (WOE_Timer > 1 ? "s" : "") + ".";
			mes "While you have to participate for " + .min_time +" minute" + (.min_time > 1 ? "s" : "") + ".";
			close;
		}
		mes "[Claim Reward]";
		mes "Do you want to claim your prize?";
		mes "You have participated in the last WoE for " + WOE_Timer + " minutes.";
		mes "Remember, if you don't claim your prize now, It will be lost once the next WoE starts!";
		next;
		switch(select("Claim the prize", "Later")) {
		case 1:
			mes "[Claim Reward]";
			mes "Thank you for participating in the War of Emperium!";
			WOE_Timer_Claimed = true;
			if(.point) {
				set getd(.points$[0]), getd(.points$[0]) + .point;
				dispbottom "Received " + .point + " " + .points$[1] + ". Total: " + getd(.points$[0]);
			}
			if(.zeny) {
				Zeny += .zeny;
				dispbottom "Received " + .zeny + " zeny.";
			}
			for(.@i = 0; .@i < .@sz; .@i += 2) {
				getitem .items[.@i],.items[.@i+1];
			}
			break;
		case 2:
			close;
		}
		close;
	case 6:
		openshop();
		end;
	case 7:
		close;
	} }
}




office,130,38,4	duplicate(WOE Information)	WOE Information#office	4_M_YATTWARP

prontera,143,97,4	duplicate(WOE Information)	Castle Warper#prt2	4_M_YATTWARP
prontera,39,213,4	duplicate(WOE Information)	Castle Warper#prt3	4_M_YATTWARP
prontera,160,326,4	duplicate(WOE Information)	Castle Warper#prt4	4_M_YATTWARP
prontera,271,213,4	duplicate(WOE Information)	Castle Warper#prt5	4_M_YATTWARP
prontera,146,35,4	duplicate(WOE Information)	Castle Warper#prt6	4_M_YATTWARP

payon,181,112,4	duplicate(WOE Information)	Castle Warper#pay1	4_M_YATTWARP
payon,168,230,4	duplicate(WOE Information)	Castle Warper#pay2	4_M_YATTWARP

aldebaran,142,124,4	duplicate(WOE Information)	Castle Warper#ald1	4_M_YATTWARP

alberta,38,240,4	duplicate(WOE Information)	Castle Warper#alb1	4_M_YATTWARP
alberta,121,59,4	duplicate(WOE Information)	Castle Warper#alb2	4_M_YATTWARP

morocc,166,109,4	duplicate(WOE Information)	Castle Warper#moc1	4_M_YATTWARP

geffen,115,73,4	duplicate(WOE Information)	Castle Warper#gef1	4_M_YATTWARP

lighthalzen,154,85,4	duplicate(WOE Information)	Castle Warper#lhz1	4_M_YATTWARP
yuno,332,108,4	duplicate(WOE Information)	Castle Warper#yuno	4_M_YATTWARP
morocc,168,261,4	duplicate(WOE Information)	Castle Warper#moc2	4_M_YATTWARP
izlude,137,94,4	duplicate(WOE Information)	Castle Warper#izl	4_M_YATTWARP