//================= Hercules Script =======================================
//=       _   _                     _
//=      | | | |                   | |
//=      | |_| | ___ _ __ ___ _   _| | ___  ___
//=      |  _  |/ _ \ '__/ __| | | | |/ _ \/ __|
//=      | | | |  __/ | | (__| |_| | |  __/\__ \
//=      \_| |_/\___|_|  \___|\__,_|_|\___||___/
//================= License ===============================================
//= This file is part of Hercules.
//= http://herc.ws - http://github.com/HerculesWS/Hercules
//=
//= Copyright (C) 2012-2015  Hercules Dev Team
//= Copyright (C)  Euphy
//= Copyright (C)  rAthena Dev Team
//= Copyright (C)  eAthena Dev Team
//=
//= Hercules is free software: you can redistribute it and/or modify
//= it under the terms of the GNU General Public License as published by
//= the Free Software Foundation, either version 3 of the License, or
//= (at your option) any later version.
//=
//= This program is distributed in the hope that it will be useful,
//= but WITHOUT ANY WARRANTY; without even the implied warranty of
//= MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//= GNU General Public License for more details.
//=
//= You should have received a copy of the GNU General Public License
//= along with this program.  If not, see <http://www.gnu.org/licenses/>.
//=========================================================================
//= Alchemist Shop
//================= Description ===========================================
//= Merchants for Alchemist Materials and Manuals.
//================= Current Version =======================================
//= 1.0
//=========================================================================

alde_alche,31,186,3	script	Craft Book Merchant#alde	4_M_ALCHE_D,{
	mes "[Craft Book Merchant]";
	mes "Welcome.";
	mes "I'm here to sell";
	mes "^0000FFspecial craft books^000000 for Geneticists.";
	next;
	mes "[Craft Book Merchant]";
	mes "Geneticists have some skills";
	mes "that require craft books to activate.";
	next;
	mes "[Craft Book Merchant]";
	mes "The more craft books you have,";
	mes "the more skills you can use.";
	next;
	mes "[Craft Book Merchant]";
	mes "Please understand that";
	mes "I specialize in the sale of these special books and";
	mes "I ^FF0000don't sell other items^000000.";
	next;
	mes "[Craft Book Merchant]";
	mes "Would you like to take a look at my craft books?";
	next;
	if(select("Sure.", "No.") == 2) {
		mes "[Craft Book Merchant]";
		mes "Thank you for visiting my shop.";
		mes "Please be safe on your travels.";
		close;
	}
	if (checkweight(Knife,1) == 0) {
		mes "[Craft Book Merchant]";
		mes "I'm sorry, but your inventory is almost full.";
		mes "Please empty your inventory first.";
		close;
	}
	if (MaxWeight - Weight < 2500) {
		mes "[Craft Book Merchant]";
		mes "Please empty your inventory first.";
		close;
	}
	mes "[Craft Book Merchant]";
	mes "Okay then, here's the list of available craft books.";
	next;
	switch(select("[Apple Bomb Craft Book] 100,000 zeny", "[Pineapple Bomb Craft Book] 100,000 zeny", "[Coconut Bomb Craft Book] 100,000 zeny", "[Melon Bomb Craft Book] 100,000 zeny", "[Banana Bomb Craft Book] 100,000 zeny", "[Plant Gene Cultivation Method] 100,000 zeny", "[Superior Potion Craft Manual] 100,000 zeny", "[Mix Cooking Book] 100,000 zeny", "[Health Improvement Research Book] 100,000 zeny", "[Vigor Drink Recipe] 100,000 zeny", "Close")){
	case 1: .@item = 6279; break;
	case 2: .@item = 6280; break;
	case 3: .@item = 6281; break;
	case 4: .@item = 6282; break;
	case 5: .@item = 6283; break;
	case 6: .@item = 6284; break;
	case 7: .@item = 6285; break;
	case 8: .@item = 11022; break;
	case 9: .@item = 11023; break;
	case 10: .@item = 11024; break;
	case 11:
		mes "[Craft Book Merchant]";
		mes "Thank you for your patronage.";
		mes "Please come again.";
		close;
	}
	mes "[Craft Book Merchant]";
	mes "^0000FF["+getitemname(.@item)+"] costs";
	mes "100,000 zeny.";
	mes "How many would you like to purchase?";
	next;
	input .@amount;
	if (.@amount == 0) {
		mes "[Craft Book Merchant]";
		mes "Would you like to see some different books?";
		close;
	}
	if (.@amount < 1 || .@amount > 99 ){
		mes "[Craft Book Merchant]";
		mes "You cannot purchase more than 100 at a time.";
		close;
	}
	mes "[Craft Book Merchant]";
	mes "You've entered "+.@amount+"x ^0000FF["+getitemname(.@item)+"]^000000 to be purchased.";
	mes "Would you like to continue?";
	next;
	if (select("Yes", "No") == 1) {
		.@total = .@amount * 100000;
		if (Zeny < .@total) {
			mes "[Craft Book Merchant]";
			mes "I'm sorry, but you don't have enough money.";
			close;
		}
		if (checkweight(.@item,.@amount) == 0){
			mes "[Craft Book Merchant]";
			mes "It doesn't seem like you can carry everything.";
			mes "Please check the space in your inventory.";
			close;
		}
		mes "[Craft Book Merchant]";
		mes "Thank you for your patronage.";
		Zeny -= .@total;
		getitem .@item,.@amount;
		close;
	}
	mes "[Craft Book Merchant]";
	mes "Please take your time";
	mes "before you make your decision.";
	close;
}
