office,132,36,3	script	Reset Event#4	4_F_MAYSEL,{
	if (countitem(Reset_Coupon)) {
		mes "[^FF0000Maysel^000000]";	
		mes "Oh you have FREE RESET Coupon.";
		mes "Would you like to use it?";
		next;
		if (select("No, maybe later.", "Yes, Reset me now.") == 2) {
			if (checkcart() || checkfalcon() || checkmount()) {
				mes "[^FF0000Maysel^000000]";
				mes "Oh! Please remove your ^FF3355PUSHCART^000000, ^FF3355PECOPECO^000000 or ^FF3355FALCON^000000 before proceeding with the SKILL RESET.";
				close;
			}
			delitem Reset_Coupon,1;
			specialeffect(EF_ANGEL, AREA, playerattached());
			specialeffect(EF_TRUESIGHT, AREA, playerattached());
			sc_end SC_ALL;
			resetstatus;
			resetskill;
			mes "[^FF0000Maysel^000000]";
			mes "There you go!!!";
			close;
		}
	}	
	if(#TSRESET) {
		mes "[^FF0000Maysel^000000]";
		mes "You already used this service.";
		close;
	}
	query_sql("SELECT count(`referral_id`) FROM referral WHERE `referral_id` = "+getcharid(CHAR_ID_ACCOUNT)+" AND `redeemed` = 1", .@refcount);
	mes "[^FF0000Maysel^000000]";
	mes "I am happy to see you here brave adventurer!";
	next;
	mes "[^FF0000Maysel^000000]";
	mes "I can offer a FREE Skill and Stat Reset for everyone but we ask for your cooperation.";
	next;
	mes "[^FF0000Maysel^000000]";
	mes "Remember I can only process ^28bf00one (1) character^000000 in this account.";
	mes "Your tasks are:";
	mes "^28bf00Tag & Share^000000: "+countitem(Tag_Share_Event)+" / 1";
	mes "^28bf00Valid Referral^000000: "+.@refcount+" / 5";
	mes "^28bf00Online Points^000000: "+#PCTIME+" / 100";
	if ( countitem(Tag_Share_Event) > 0 && .@refcount > 4 && #PCTIME > 99 ) {
		next;
		mes "[^FF0000Maysel^000000]";
		mes "Wow!!!.  Thank you for helping us to grow.  Shall we proceed with the reset now?";
		next;
		if (select("No, maybe later.", "Yes, Reset me now.") == 1) {
			mes "[^FF0000Maysel^000000]";
			mes "Okay, let me know when you are ready.";
			close;
		}	
		if (checkcart() || checkfalcon() || checkmount()) {
			mes "[^FF0000Maysel^000000]";
			mes "Oh! Please remove your ^FF3355PUSHCART^000000, ^FF3355PECOPECO^000000 or ^FF3355FALCON^000000 before proceeding with the SKILL RESET.";
			close;
		}
		#TSRESET=1;
		delitem Tag_Share_Event,1;
		set #PCTIME,#PCTIME-100;
		specialeffect(EF_ANGEL, AREA, playerattached());
		specialeffect(EF_TRUESIGHT, AREA, playerattached());
		sc_end SC_ALL;
		resetstatus;
		resetskill;
		mes "[^FF0000Maysel^000000]";
		mes "There you go!!!";
		close;
	}
	
	while(1) {
		next;
		switch(select(
		"^777777How to Join Tag&Share^000000:"+
		"^777777How to Join Referral^000000:"+
		"^777777Close^000000"
		)) {
		case 1: // Tag & Share
			mes "[^FF0000Tag & Share Event^000000]";
			mes "Visit our website https://classicro.net and click referral link.";
			cutin "referral",4;
			next;
			mes "[^FF0000Tag & Share Event^000000]";
			mes "Click your FB Share Button.";
			cutin "referral2",4;
			next;
			mes "[^FF0000Tag & Share Event^000000]";
			mes "1. Tag atleast 10 friends, make sure it is PUBLIC shared in your TIMELINE.";
			mes "2. Screenshot the link found in your timeline and send to our Facebook Page.";
			mes "https://www.facebook.com/Free2PlayAsia";
			mes "3. Upon verification will send you ^FF0000Social Network Event Ticket^000000 as proof of your share.";
			cutin "tagshare",4;
			break;
		case 2: // Referral
			cutin "",255;
			mes "[^FF0000Referral Program^000000]";
			mes "Anyone ^FF0000REGISTER^000000 by clicking your shared link, they will automatically become your referred player.";
			mes "Monitor their progress by typing ^FF0000@referral^000000.";
			mes "1. We need atleast ^FF0000five (5)^000000 referred player to reach ^FF0000Base Level 75^000000";
			break;
		case 3: // Close
			cutin "",255;
			close;
		}
	}		
	close;			
}