tur_dun01,156,36,5	script	Survival Instructor#jr01	1_M_ORIENT01,{
	mes "[Survival Instructor, Rescue]";
	if (BaseJob == Job_Hunter) {
		if (job_ranger01 < 1) {
			mes "eeeeei~ ha!";
			mes "The weather is really great.";
			next;
			mes "[Survival Instructor, Rescue]";
			mes "What's up?";
			mes "The monsters here are a";
			mes "little tough so be careful.";
			next;
			if(select("I came here to become to a Ranger.", "I just came to look around.") == 2) {
				mes "[Survival Instructor, Rescue]";
				mes "Oh ya?";
				mes "The weather is really great. Shall we take a picture to commemorate it?";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "No?";
				mes "Then just look around quietly and then go back.";
				close;
			}
			mes "[Survival Instructor, Rescue]";
			mes "Huh?";
			mes "How did you find me?";
			next;
			mes "[Survival Instructor, Rescue]";
			mes "Well, it's a passing mark that you recognize me... let me see.";
			next;
			if (BaseLevel < 99 || JobLevel < 50) {
				mes "[Survival Instructor, Rescue]";
				mes "No.";
				mes "I can tell just by looking at you that you seem to be inexperienced.";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "Have more pride in your job and get more experience, and then when you grow as a Hunter or a Sniper you can make an aura by yourself, please come back again.";
				close;
			}
			mes "[Survival Instructor, Rescue]";
			mes "Ok!";
			mes "It looks like you have";
			mes "enough experience.";
			next;
			mes "[Survival Instructor, Rescue]";
			mes "Good.";
			mes "First of all, let me tell you the job change qualifications to be a Ranger.";
			next;
			mes "[Survival Instructor, Rescue]";
			mes "I've already checked the first qualification that you've experienced enough to make an aura as a Hunter or a Sniper.";
			next;
			mes "[Survival Instructor, Rescue]";
			mes "For the second qualification to judge one's ability exactly, you need to lighten your body and mind.";
			next;
			if (Class == Job_Hunter || Class == Job_Baby_Hunter) {
				mes "[Survival Instructor, Rescue]";
				mes "Ah wait, before that.";
				mes "When you change a job into a Ranger from a Hunter,";
				mes "you won't get any chance to learn the skills of a Sniper, would that be okay?";
				next;
				switch(select("I'll think about it more.", "I want to be a Ranger already.")) {
				case 1:
					mes "[Survival Instructor, Rescue]";
					mes "Okay.";
					mes "Take your time to think, if it's okay then come back.";
					close;
				case 2:
					mes "[Survival Instructor, Rescue]";
					mes "All right.";
					mes "You are ready then.";
					next;
				}
				mes "[Survival Instructor, Rescue]";
				mes "Well let's continue our conversation.";
				mes "Before you change into a Ranger, even though you reached the highest level of a Hunter, it is not the best evaluation of your abilities.";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "So in order to check your abilities, I'll need to evaluate your pure abilities.~";
				next;
			} else {
				mes "[Survival Instructor, Rescue]";
				mes "Before you change into a Ranger, even though you reached the highest level of a Sniper, it is not the best evaluation of your abilities.";
				next;
				mes "[Survival Instructor]";
				mes "So in order to check your abilities, I'll need to evaluate your pure abilities.~";
				next;
			}
			mes "[Survival Instructor, Rescue]";
			mes "To do this you need to be cleansed of body and soul.";
			mes "Make sure that your weight equals '0' to continue.";
			job_ranger01 = 1;
			setquest 8254;
			close2;
			warp "alberta",117,57;
			end;
		} else if (job_ranger01 == 1) {
			//if (Weight < 1) {
				mes "Wow, you've come back so quickly.";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "Ok, now I'll talk about the requirements to take the test to become a Ranger.";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "All the tests to become a Ranger are going to be done with practical means.";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "Will there be a written test?";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "Why do you want one?";
				mes "The most important part of this test is the test of your experience on the battlefield.";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "Therefore, what I request of you is to prove your power of survival.";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "I want to see the real power of survival, even if you fall down and get beat up.";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "If you succeed with this survival power test, you will receive the first qualification.";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "Well, let's talk about the details when you get the qualification for taking the test.";
				mes "When you want to take the survival power test, please talk to me again.";
				job_ranger01 = 2;
				changequest 8254,8255;
				close;
			//}
			//mes "Before you change into a Ranger, I'll need to evaluate your pure abilities.";
			//next;
			////mes "[Survival Instructor, Rescue]";
			//mes "To do this you need to be cleansed of body and soul.";
			//mes "Make sure that your weight equals 0 to continue.";
			//close;
		} else if (job_ranger01 == 2) {
			//if (Weight < 1) {
				mes "Um. That you talked to me again means that you are determined to change into a Ranger and take the survival power test.";
				next;
				if(select("I'll think about it more", "I'll take the test") == 1) {
					mes "[Survival Instructor, Rescue]";
					mes "Prepare yourself very well before taking this test.";
					next;
					mes "[Survival Instructor, Rescue]";
					mes "Think about it well and come back.";
					close;
				}
				mes "[Survival Instructor, Rescue]";
				mes "If you are determined, then there's nothing to wait for.";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "I'll explain it simply.";
				mes "What I'm going to provide you is 10 Fly Wings, 500 of Arrows and 1 test Bow.";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "Take the provided items and all you have to do for the survival power test is ^0000ffgo to the Northwestern area of Turtle Island and find Instructor Teardrop^000000.";
				mes "Easy, right?";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "Remember that you don't have any other equipment on, so be careful of the monsters.";
				mes "Ready to start?";
				next;
				if(select("Wait a second", "Yes, I'm ready") == 1) {
					mes "[Survival Instructor, Rescue]";
					mes "What kind of preparation can be so long.";
					next;
					mes "[Survival Instructor, Rescue]";
					mes "Come again when you are absolutely ready.";
					close;
				}
				mes "[Survival Instructor, Rescue]";
				mes "Well, then let's start.";
				mes "There's no time to hesitate.";
				mes "Do your best.";
				job_ranger01 = 3;
				changequest 8255,8256;
				getitem Bow__,1;
				getitem N_Fly_Wing,10;
				getitem Arrow,500;
				close;
			//}
			//mes "I knew it.";
			////next;
			//mes "[Survival Instructor, Rescue]";
			//mes "Why did you bring so much?";
			//mes "It's good that you do your best on the job change but, the key to this test is to test our true abilities...";
			//next;
			//mes "[Survival Instructor, Rescue]";
			//mes "If you don't make your weight 0, you wouldn't be able to take the test.";
			//close;
		} else if (job_ranger01 == 3) {
			mes "Umm?";
			mes "What are you waiting for?";
			next;
			if(select("Tell me the mission again.", "I just wanted to talk.") == 1) {
				mes "[Survival Instructor, Rescue]";
				mes "Oh, ya.";
				mes "Is this the mind of a person who's going to take the test?";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "Stay alert and listen.";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "Take the provided items and all you have to do for the survival power test is ^0000ffgo to the Northwestern area of Turtle Island and find Instructor Teardrop^000000.";
				mes "Isn't that so easy?";
				next;
				mes "[Survival Instructor, Rescue]";
				mes "As you don't have any equipment on, be careful of the monsters in the field.";
				mes "Well, shall we start?";
				next;
				if(select("Wait a minute", "I will start") == 1) {
					mes "[Survival Instructor, Rescue]";
					mes "What kind of preparation can be so long.";
					next;
					mes "[Survival Instructor, Rescue]";
					mes "Come again when you are absolutely ready.";
					close;
				}
				mes "[Survival Instructor, Rescue]";
				mes "Okay, let's start.";
				mes "There's no time to hesitate, so do your best.";
				close;
			}
			mes "[Survival Instructor, Rescue]";
			mes "I don't think you have the time for that.";
			next;
			mes "[Survival Instructor, Rescue]";
			mes "Hurry up and finish the test.";
			close;
		} else if (job_ranger01 > 3 && job_ranger01 < 7) {
			mes "Are you still wandering about here?";
			next;
			mes "[Survival Instructor, Rescue]";
			mes "Well, if you are an easy person, that's none of my business but if you decided once, wouldn't it be better to take the practical test in a minute and meet me after becoming a Ranger?";
			close;
		} else if (job_ranger01 == 7) {
			mes "Oh, hey. What are you doing here?";
			next;
			mes "[Survival Instructor, Rescue]";
			mes "Because you've disappeared suddenly, the Ranger Master was looking for you.";
			mes "Do you want to go to him now?";
			next;
			switch(select("Don't go", "Go")) {
			case 1:
				mes "[Survival Instructor, Rescue]";
				mes "Are you busy with something else?";
				close;
			case 2:
				mes "[Survival Instructor, Rescue]";
				mes "Then I'll send you, please be well.";
				close2;
				warp "job3_rang01",89,38;
				end;
			}
		}
		mes "Oh, hey. Who's this?";
		next;
		mes "[Survival Instructor, Rescue]";
		mes "Hey, you look great.";
		mes "Congratulations on becoming a Ranger~";
		next;
		mes "[Survival Instructor, Rescue]";
		mes "Next time, try not to intimidate other people.";
		close;
	}
	if (Class == Job_Ranger || Class == Job_Ranger_T || Class == Job_Baby_Ranger) {
		if (job_ranger01 == 8) {
			mes "Ho. Who's this~";
			mes "You really look talented...";
			next;
			mes "[Survival Instructor, Rescue]";
			mes "Next time, try not to intimidate other people.";
			close;
		}
	}
	mes "Ha ~ ha.";
	mes "The weather is really great.";
	next;
	mes "[Survival Instructor, Rescue]";
	mes "What's up?";
	mes "The monsters here are a";
	mes "little tough so be careful.";
	close;
}

tur_dun01,91,169,3	script	Test Instructor#jr02	4_M_JOB_HUNTER,{
	mes "[Test Instructor, Teardrop]";
	if (BaseJob == Job_Hunter) {
		if (job_ranger01 < 3) {
			mes "Good to goooooo!!!!!!!";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "Huh? Who are you? What are you doing here, you baby archer.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "May I tell you one thing?";
			mes "If you want to change a job to a Ranger, first talk to Survival Instructor Rescue.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "Then he will tell you the requirement for the job change test!!!";
			close;
		} else if (job_ranger01 == 3) {
			mes "Good to goooooo!!!!!!!";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "Huh? Who are you? What are you doing here, you baby archer.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "That you are coming and going bugs me so, would you please stop?!";
			next;
			if(select("Ranger practical test building?", "I came for the test.") == 1) {
				mes "[Test Instructor, Teardrop]";
				mes "What, what are you...?";
				next;
				mes "[Test Instructor, Teardrop]";
				mes "What do you think you are looking at?";
				next;
				mes "[Test Instructor, Teardrop]";
				mes "How could you be a Ranger if you can't even recognize what's in front of you? Get out of here!";
				close;
			}
			mes "[Test Instructor, Teardrop]";
			mes "Ho, having come this far, it means you've passed the first survival test.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "But, can you be sure that there wasn't any cheating?";
			next;
			/*
			if (Weight > 500) {
				mes "[Test Instructor, Teardrop]";
				mes "See, I knew it.";
				next;
				mes "[Test Instructor, Teardrop]";
				mes "Having done the test normally, you would have adjusted your weight to 0, and hold the items provided by Rescue!";
				mes "But, how come you weigh so much?";
				next;
				mes "[Test Instructor, Teardrop]";
				mes "I consider this as cheating!";
				mes "Come and see me again!";
				close2;
				warp "tur_dun01",162,33;
				end;
			}
			*/
			mes "[Test Instructor, Teardrop]";
			mes "Hmm. It's doubtful...";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "I don't smell any signs of cheating. For now...";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "Before taking a practical test, I want to eat something.";
			mes "You know the food situation isn't always so good in a foreign land.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "I know that the very basic way to survive might be raising the strength of one's own body. But, I find that sending adventurers is easier for me.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "So, kill ^0000ff1 Dragon Tail^000000 and bring me ^0000ff1 Wing of Dragonfly^000000.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "If you run out of the provided items, we cannot support you more so take care.";
			mes "Consider this as an extension of the survival power test.";
			job_ranger01 = 4;
			changequest 8256,8257;
			close;
		} else if (job_ranger01 == 4) {
			if (questprogress(8257,HUNTING) == 2) {
				if (countitem(Dragon_Fly_Wing) > 0) {
					mes "Oh! Oh! Woooooow!";
					mes "You've brought it! Let me see...";
					next;
					mes "[Test Instructor, Teardrop]";
					mes "Hmmmm, it's still hot?!";
					mes "You don't seem to be hurt anywhere...";
					next;
					mes "[Test Instructor, Teardrop]";
					mes "Good, for now you're qualified for the practical test.";
					next;
					mes "[Test Instructor, Teardrop]";
					mes "Well, before I explain, could you please give me that Dragonfly wing?";
					mes "You've heard the saying, 'in any situation, eating comes first'?";
					delitem Dragon_Fly_Wing,1;
					job_ranger01 = 5;
					changequest 8257,8258;
					close;
				}
			}
			mes "What are you doing there? Standing with a blank look.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "I'm hungry.";
			mes "Before taking the practical test, I want to eat something.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "I know that the very basic way to survive might be raising the strength of one's own body. But, I find that sending adventurers is easier for me.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "So, kill ^0000ff1 Dragon Tail^000000 and bring me ^0000ff1 Dragon Fly Wing^000000.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "If you run out of the provided items, we cannot support more so take care.";
			mes "Consider this as an extension of the survival power test.";
			close;
		} else if (job_ranger01 == 5) {
			mes "Awooo. Yumyum.";
			mes "Eh? What are you looking at?";
			mes "You want to eat some?";
			next;
			switch(select("Oh, just eat up", "...")) {
			case 1:
				mes "[Test Instructor, Teardrop]";
				mes "Why aren't you eating?";
				mes "It's quite edible.";
				mes "If you cover it with rice, it's like roasted seaweed, very tasty and delicious.";
				next;
				mes "[Test Instructor, Teardrop]";
				mes "You need to be strong enough not to be so picky with such things...";
				next;
				break;
			case 2:
				mes "["+strcharinfo(PC_NAME)+"]";
				mes "No thanks... anyway...";
				next;
				mes "[Test Instructor, Teardrop]";
				mes "Hmm? Oh my, oh my, I've shown you my sloppiness.";
				next;
				break;
			}
			mes "[Test Instructor, Teardrop]";
			mes "Ok, I'll send you to the practical test field.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "The practical test consists of 3 parts in total.";
			mes "It's to recheck the things you've learned as a hunter or a sniper, so there's nothing much to be worried.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "If you get a passing mark over three tests, you'll be on your way to becoming a Ranger.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "I'll explain the paths for the test.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "Once you get into the test field, a staff will be waiting for you. Go into the room made by the staff, and standby.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "The test is done one by one so, if there's many people, you might need to wait.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "The first test is to test of how keen your eyes are.";
			mes "Different monsters will appear in 8 places. Kill only the monster named 'Poring' and you get a point, when you reach a certain mark, then you pass. Easy, huh?";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "The second test is about how much you can use a trap efficiently.";
			mes "Get rid of monsters and do the mission by using only the provided traps, and you pass. Just be careful not to be engulfed by the explosion.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "For the 3rd test, when you become a Ranger you can handle a wolf, so you will be tested on how well you can handle such an animal.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "When you remove a bomb by using the given wolf, you get points. You pass when you get a certain mark on the test.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "The staff there will tell you more details as well.";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "Now, I will enter you into the practical test field, is your preparation all done?";
			next;
			if(select("Please wait a little", "Let's go to the practical test field!") == 1) {
				mes "[Test Instructor, Teardrop]";
				mes "Um? Aren't you ready?";
				next;
				mes "[Test Instructor, Teardrop]";
				mes "Well. To be careful is good.";
				mes "Come back when you are ready.";
				close;
			}
			callsub L_Start,0;
			close;
		} else if (job_ranger01 == 6) {
			mes "Good to goooooo!!!!!!!";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "Um? What happened?";
			mes "Why are you walking about here? What about the test?";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "Aha... You've failed the middle!";
			mes "You are such a fool.";
			emotion e_gg;
			next;
			mes "[Test Instructor, Teardrop]";
			mes "So what are you going to do? Try again?";
			next;
			switch(select("Wait a minute", "Go to the practical test field!", "I give up the job change.")) {
			case 1:
				mes "[Test Instructor, Teardrop]";
				mes "Um? Aren't you ready yet?";
				next;
				mes "[Test Instructor, Teardrop]";
				mes "All right. To be careful is good.";
				mes "Come when you are ready.";
				close;
			case 2:
				callsub L_Start,1;
				close;
			case 3:
				mes "[Test Instructor, Teardrop]";
				mes "Um? What, you're kidding huh?";
				next;
				mes "[Test Instructor, Teardrop]";
				mes "Think again.";
				mes "Do you really want to give up the job change to become a Ranger?";
				next;
				switch(select("No, I'll try again", "I give up!")) {
				case 1:
					mes "[Test Instructor, Teardrop]";
					mes "Hey. You were kidding after all?";
					next;
					mes "[Test Instructor, Teardrop]";
					mes "It's not funny so don't do that kind of joke again.";
					close;
				case 2:
					mes "[Test Instructor, Teardrop]";
					mes "You don't have as many guts as I thought.";
					nude;
					next;
					if (countitem(Bow__) > 0) {
						mes "[Test Instructor, Teardrop]";
						mes "Okay. I'll respect your opinion.";
						mes "I'll cancel the job change request from "+strcharinfo(PC_NAME)+".";
						delitem Bow__,1;
						job_ranger01 = 0;
						for(.@i = 8254; .@i <= 8262; ++.@i)
							if (questprogress(.@i))
								erasequest .@i;
						close;
					}
					mes "[Test Instructor, Teardrop]";
					mes "Huh? Where's the bow that I gave you for the practical tests?";
					next;
					mes "[Test Instructor, Teardrop]";
					mes "If you don't return it, I can't cancel you job change request.";
					close;
				}
			}
		} else if (job_ranger01 == 7) {
			mes "Oh, hey. What are you doing here?";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "Because you've disappeared suddenly, the Ranger Master was looking for you.";
			mes "Do you want to go to him now?";
			next;
			switch(select("Don't go", "Go")) {
			case 1:
				mes "[Test Instructor, Teardrop]";
				mes "Are you busy with something else?";
				close;
			case 2:
				mes "[Test Instructor, Teardrop]";
				mes "Then I'll send you, please be well.";
				close2;
				warp "job3_rang01",89,38;
				end;
			}
		}
		mes "Wow. Who's this?";
		next;
		mes "[Test Instructor, Teardrop]";
		mes "It seems that your dull eyes became somewhat keen now?";
		next;
		mes "[Test Instructor, Teardrop]";
		mes "Then, enjoy an adventure well as a Ranger.";
		close;
	}
	mes "Good to gooooooooooooooo!!!!!!";
	next;
	mes "[Test Instructor]";
	mes "Huh? What are you? Where are you from?";
	mes "Don't hang around here doing nothing. This is my area!";
	close;
L_Start:
	if (getmercinfo(1)) {
		mes "[Test Instructor, Teardrop]";
		mes "Stop!";
		next;
		mes "[Test Instructor, Teardrop]";
		mes "Where do you think you're going with that mercenary?!";
		next;
		mes "[Test Instructor, Teardrop]";
		mes "If you don't cancel the mercenary, you cannot get into the test field! Cancel it first!";
		close;
	}
	if (getarg(0) == 1) {
		if (countitem(Desert_Wolf_Babe_Scroll)) {
			mes "[Test Instructor, Teardrop]";
			mes "What, what is this?";
			mes "You shouldn't keep this around!";
			delitem Desert_Wolf_Babe_Scroll,countitem(Desert_Wolf_Babe_Scroll);
			next;
		}
		if (countitem(Bombring_Box)) {
			mes "[Test Instructor, Teardrop]";
			mes "What, what is this, a Bombring Capsule.";
			mes "You shouldn't keep such a dangerous thing!";
			delitem Bombring_Box,countitem(Bombring_Box);
			next;
		}
		if (countitem(Approval_Report)) {
			mes "[Test Instructor, Teardrop]";
			mes "What, what are all these Documents?";
			mes "I think I know. You were going to send this to Caution, right?";
			next;
			mes "[Test Instructor, Teardrop]";
			mes "If you hold such thing it would disturb your practical test so I'll take this.";
			delitem Approval_Report,countitem(Approval_Report);
			next;
		}
	}
	/*
	if (Weight > 500) {
		mes "[Test Instructor, Teardrop]";
		mes "Well, then let's gooooooooo.... oo,um?";
		next;
		mes "[Test Instructor, Teardrop]";
		mes "Hey, what are you hiding there?";
		mes "I've pointed it out for several times, you should not even think to go in there secretly with anything other than the provided items!";
		next;
		mes "[Test Instructor, Teardrop]";
		mes "You'd better lighten your weight.";
		close;
	}
	*/
	mes "[Test Instructor, Teardrop]";
	mes "See, for the last time, I warn you that cheating is strictly banned.";
	next;
	if (countitem(Arrow) < 100) {
		mes "[Test Instructor, Teardrop]";
		mes "Okay, once again I'll provide you with arrows, then I'll let you in.";
		.@arrow = 1;
		next;
	}
	mes "[Test Instructor, Teardrop]";
	mes "Good luck.";
	mes "Become a Ranger and we shall meet again.";
	job_ranger01 = 6;
	if (getarg(0) == 0)
		changequest 8258,8259;
	else {
		erasequest 8260;
		erasequest 8261;
	}
	if (.@arrow) getitem Arrow,100;
	close2;
	warp "job3_rang01",30,36;
	end;
}
