prontera,146,80,0	script	Iris	4_F_FAIRYKID3,{
	if (hopequest == 0) {
		.@eac = eaclass();
		if ( BaseLevel < 20 || BaseLevel > 60 || .@eac&EAJL_UPPER ) {
			mes "[Iris]";
			mes "I don't need the strongest one, I need the one with purest heart.";
			close;	
		}
		mes "[Iris]";
		mes "I've been traveling to different dimension seeking for help, I hope in midgard I can found someone who able to help me.";
		next;
		mes "[Iris]";
		mes "I don't need the strongest one, I need the one with purest heart.";
		next;
		mes "[Iris]";
		mes "Do you have the pure heart?";
		next;
		if (select("No", "Yes") == 1) {
			mes "[Iris]";
			mes "Well, come back to me when you are ready on this.";
			close;		
		}
		mes "[Iris]";
		mes "I will give you several test to test your endurance, patient, and loyalty.";
		next;
		mes "[Iris]";	
		mes "Go and kill 1000 poring. Come back to me when you are done.";
		setquest 30005;	
		set hopequest,1;
		close;
	}
	else if (hopequest == 1) {
		if (questprogress(30005,HUNTING) == 1) {
			mes "[Iris]";
			mes "Go and kill 1000 Porings. Come back to me when you are done.";
			close;
		} else if (questprogress(30005,HUNTING) == 2) {
			mes "[Iris]";
			mes "It was very lucky for me to ask you this favor.";
			next;
			mes "[Iris]";
			mes "Please bring me ^FF0000 1000 ^000000 ^FF0000Sticky Mucus^000000.";
			changequest 30005,30006;
			set hopequest,2;
			specialeffect(EF_ANGEL, AREA, playerattached());
			specialeffect(EF_TRUESIGHT, AREA, playerattached());
			close;
		}
	}
	else if (hopequest == 2) {
		if (countitem(Sticky_Mucus) > 999) {
			mes "[Iris]";
			mes "There!!! Thank you for that stuff.";
			delitem Sticky_Mucus, 1000;
			changequest 30006,30007;
			set hopequest,3;
			specialeffect(EF_ANGEL, AREA, playerattached());
			specialeffect(EF_TRUESIGHT, AREA, playerattached());
			close;
		} else {
			mes "[Iris]";
			mes "Where is the Sticky Mucus I asked? Come back to me when you are done collecting.";
			close;
		}
	}
	else if (hopequest == 3) {
		mes "[Iris]";
		mes "I guess you are very exhausted at this time after collecting these materials.";
		next;
		mes "[Iris]";
		mes "I just need 1 more thing from you.";
		next;
		mes "[Iris]";
		mes "You need to give me your 5 online points.";
		next;
		if (select("No - You scammer!!!", "Yes - I have plenty of those.") == 1) {
			mes "[Iris]";
			mes "Its just 5 online points. Come back when you have plenty of those.";
			close;					
		} 
		if (#PCTIME > 4) {
			mes "[Iris]";
			mes "Thank you for this online points.";
			changequest 30007,30008;
			set hopequest,4;
			set #PCTIME,#PCTIME-5;
			specialeffect(EF_ANGEL, AREA, playerattached());
			specialeffect(EF_TRUESIGHT, AREA, playerattached());					
			close;
		} else {
			mes "[Iris]";
			mes "Sorry, but you don't have enough online points.  You will have to stay online more and convert to points at the Office.";
			close;
		}
	}
	else if (hopequest == 4) {
		mes "[Iris]";
		mes "I can see it you already fullfill all the requirement.";
		next;
		mes "[Iris]";
		mes "Now go to payon, meet someone named Fenrir just outside the Palace. Talk to him until you can convince him to help me on some task.";
		close;
	}
	else if (hopequest == 5) {
		mes "[Iris]";
		mes "Thank you for that message. I am truly lucky to have you.";
		next;
		mes "[Iris]";
		mes "Accept this reward as token of gratitude.";
		set hopequest,6;
		completequest 30009;
		getitem Drosera_Hairpin,1;
		getitem Falcon_Mask,1;
		close;
	}
	else if (hopequest == 6 ) {
		mes "[Iris]";
		mes "...";
		close;
	}
	end;
}

payon,154,228,0	script	Fenrir	4_F_FAIRYKID5,{
	if (hopequest == 4) {
		mes "[Fenrir]";
		mes "Okay!!! I give up. Tell Iris I will come to help her.";
		specialeffect(EF_ANGEL, AREA, playerattached());
		specialeffect(EF_TRUESIGHT, AREA, playerattached());
		changequest 30008,30009;
		set hopequest,5;
		close;

	} 
	else if (hopequest == 5) {
		mes "[Fenrir]";
		mes "Go back to Iris and tell her that I am willing to help her.";
		close;
	} else {
		mes "[Fenrir]";
		mes "....";
		close;
	}
}