//================= Hercules Script =======================================
//=       _   _                     _
//=      | | | |                   | |
//=      | |_| | ___ _ __ ___ _   _| | ___  ___
//=      |  _  |/ _ \ '__/ __| | | | |/ _ \/ __|
//=      | | | |  __/ | | (__| |_| | |  __/\__ \
//=      \_| |_/\___|_|  \___|\__,_|_|\___||___/
//================= License ===============================================
//= This file is part of Hercules.
//= http://herc.ws - http://github.com/HerculesWS/Hercules
//=
//= Copyright (C) 2012-2015  Hercules Dev Team
//= Copyright (C)  Euphy
//=
//= Hercules is free software: you can redistribute it and/or modify
//= it under the terms of the GNU General Public License as published by
//= the Free Software Foundation, either version 3 of the License, or
//= (at your option) any later version.
//=
//= This program is distributed in the hope that it will be useful,
//= but WITHOUT ANY WARRANTY; without even the implied warranty of
//= MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//= GNU General Public License for more details.
//=
//= You should have received a copy of the GNU General Public License
//= along with this program.  If not, see <http://www.gnu.org/licenses/>.
//=========================================================================
//= Port Malaya Guides
//================= Description ===========================================
//= Guides for the city of Malaya.
//================= Current Version =======================================
//= 1.1
//=========================================================================

malaya,71,72,4	script	Port Malaya Guide#01::GuideMalaya	4_F_BARYO_WOMAN,{
	mes "[Port Malaya Guide]";
	mes "Welcome to ^8B4513Port Malaya^000000, the Breathing Village.";
	mes "Where cultures and legends come to life!";
	mes "Do you need help navigating the village?";
	F_Navi("[Port Malaya Guide]");
	while(1) {
		next;
		switch(select("[ Kafra Employees ]", "[ Inn & Tavern ]", "[ Weapon & Armor Shop ]", "[ Tool Shop ]", "[ Hospital ]", "[ Park ]", "[ Harbor ]", "Remove marks from Mini-Map", "Cancel")) {
		case 1:
			callsub L_Mark, "^0000FFKafra Employees^000000",1;
			viewpoint 1,71,79,0,0x0A82FF;
			viewpoint 1,234,204,1,0x0A82FF;
			break;
		case 2:
			callsub L_Mark, F_Navi("Inn & Tavern","malaya,193,215","^006400");
			viewpoint 1,193,215,2,0xAAFF00;
			break;
		case 3:
			callsub L_Mark, F_Navi("Weapon & Armor Shop","malaya,114,212","^008080");
			viewpoint 1,114,212,3,0x4F543C;
			break;
		case 4:
			callsub L_Mark, F_Navi("Tool Shop","malaya,297,167","^FF1493");
			viewpoint 1,297,167,4,0xFF1493;
			break;
		case 5:
			callsub L_Mark, F_Navi("Hospital","malaya,50,75","^8B4513");
			viewpoint 1,50,75,5,0x8B4513;
			break;
		case 6:
			callsub L_Mark, F_Navi("Park","malaya,280,371","^8B4513");
			viewpoint 1,280,371,6,0x8B4513;
			break;
		case 7:
			callsub L_Mark, F_Navi("Harbor","malaya,276,55","^8A2BE2");
			viewpoint 1,276,55,7,0x8A2BE2;
			break;
		case 8:
			mes "[Port Malaya Guide]";
			mes "I'll remove all marks from your mini-map.";
			mes "Is there anything else I can do for you?";
			viewpoint 2,1,1,0,0xFFFFFF;
			viewpoint 2,1,1,1,0xFFFFFF;
			viewpoint 2,1,1,2,0xFFFFFF;
			viewpoint 2,1,1,3,0xFFFFFF;
			viewpoint 2,1,1,4,0xFFFFFF;
			viewpoint 2,1,1,5,0xFFFFFF;
			viewpoint 2,1,1,6,0xFFFFFF;
			viewpoint 2,1,1,7,0xFFFFFF;
			break;
		case 9:
			mes "[Port Malaya Guide]";
			mes "I hope you enjoy your journey.";
			close;
		}
	}
	end;
L_Mark:
	mes "[Port Malaya Guide]";
	mes "The "+getarg(0)+" "+((getarg(1,0))?"are":"is");
	mes "marked on your mini-map.";
	mes "Check your mini-map.";
	mes "Is there anything else I can do for you?";
	return;
}
malaya,250,83,6	duplicate(GuideMalaya)	Port Malaya Guide#02	4_F_BARYO_WOMAN
malaya,224,204,6	duplicate(GuideMalaya)	Port Malaya Guide#03	4_F_BARYO_WOMAN
