//================= Hercules Script =======================================
//=       _   _                     _
//=      | | | |                   | |
//=      | |_| | ___ _ __ ___ _   _| | ___  ___
//=      |  _  |/ _ \ '__/ __| | | | |/ _ \/ __|
//=      | | | |  __/ | | (__| |_| | |  __/\__ \
//=      \_| |_/\___|_|  \___|\__,_|_|\___||___/
//================= License ===============================================
//= This file is part of Hercules.
//= http://herc.ws - http://github.com/HerculesWS/Hercules
//=
//= Copyright (C) 2013-2015  Hercules Dev Team
//= Copyright (C)  Euphy
//=
//= Hercules is free software: you can redistribute it and/or modify
//= it under the terms of the GNU General Public License as published by
//= the Free Software Foundation, either version 3 of the License, or
//= (at your option) any later version.
//=
//= This program is distributed in the hope that it will be useful,
//= but WITHOUT ANY WARRANTY; without even the implied warranty of
//= MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//= GNU General Public License for more details.
//=
//= You should have received a copy of the GNU General Public License
//= along with this program.  If not, see <http://www.gnu.org/licenses/>.
//=========================================================================
//= Acolyte Warpers
//================= Description ===========================================
//= Warpers to various towns.
//================= Current Version =======================================
//= 1.0
//=========================================================================

prontera,98,121,4	script	Acolyte#Prtclear	4_F_01,{
	mes "[Keiki]";
	mes "Hello there, adventurer.";
	mes "I've been studying magic from all over Rune-Midgard to upgrade what I believe to be one of the greatest skills available to the acolyte class.";
	next;
	mes "[Keiki]";
	mes "I am the one and only Acolyte that has attained the Level 10 Warp Portal skill!";
	emotion e_dots,1;
	next;
	mes "[Keiki]";
	mes "That's right! And...";
	mes "I promise you that I don't forget locations that I have already memorized.";
	mes "One day I will level up my skills to warp to wherever I please~";
	next;
	mes "[Keiki]";
	mes "I am willing to warp you to the many locations that I have memorized for a small fee.";
	mes "Would you like to use this service?";
	next;
	switch(select("Yes", "No")) {
	case 1:
		mes "[Keiki]";
		mes "Where would you like to go to?";
		mes "I wish you goodluck on your journey.";
		next;

		setarray .@towns$[0], "Izlude", "Geffen", "Payon", "Morroc", "Alberta", "Al De Baran", "Comodo", "Umbala", "Juno";
		setarray .@maps$[0],  "izlude", "geffen", "payon", "morocc", "alberta",   "aldebaran", "comodo", "umbala", "yuno";
		setarray .@cost[0],        600,     1200,    1200,     1200,      1800,          2200,     2200,     2200,   1800;

		.@size = getarraysize(.@towns$);
		for(.@i = 0; .@i<.@size; ++.@i)
			.@menu$ += .@towns$[.@i]+" -> "+.@cost[.@i]+"z:";
		.@i = select(.@menu$+"Cancel")-1;
		if (.@i == .@size)
			close;
		if (Zeny < .@cost[.@i]) {
			mes "[Keiki]";
			mes "I'm sorry, but you don't have";
			mes "enough zeny for the Teleport";
			mes "Service. The fee to teleport";
			mes "to "+.@towns$[.@i]+" is "+.@cost[.@i]+" zeny.";
			close;
		}
		specialeffect(EF_READYPORTAL, AREA, playerattached());
		specialeffect(EF_TELEPORTATION, AREA, playerattached());
		specialeffect(EF_PORTAL, AREA, playerattached());
		next;
		Zeny -= .@cost[.@i];
		switch(.@i) {
			case 0: if (RENEWAL) warp "izlude",128,98; else warp "izlude",91,105; break;
			case 1: warp "geffen",120,39; break;
			case 2: warp "payon",161,58; break;
			case 3: warp "morocc",156,46; break;
			case 4: warp "alberta",117,56; break;
			case 5: warp "aldebaran",168,112; break;
			case 6: warp "comodo",209,143; break;
			case 7: warp "umbala",100,154; break;
			case 8: warp "yuno",158,125; break;
		}
		close;
	case 2:
		close;
	}
}

yuno,142,184,6	script	Acolyte#Junoclear	4_F_01,{
	mes "[Isalei]";
	mes "Hello, adventurer.";
	mes "My companion Keiki and I have discovered a way to increase our warp portal abilities.";
	next;
	mes "[Isalei]";
	mes "Though I have not mastered up to the level that she has, I have been able to attain Level 5.";
	emotion e_dots,1;
	next;
	mes "[Isalei]";
	mes "Maybe one day I can level up my skills enough so that I can use Warp portal to more saved locations.";
	next;
	mes "[Isalei]";
	mes "I am willing to warp you to the many locations that I have memorized for a small fee.";
	mes "Would you like to use this service?";
	next;
	switch(select("Yes", "No")) {
	case 1:
		mes "[Isalei]";
		mes "Where would you like to go to?";
		mes "I wish you goodluck on your journey.";
		next;

		setarray .@towns$[0], "Einbroch", "Lighthalzen", "Hugel", "Rachel", "Prontera";
		setarray .@maps$[0],  "einbroch", "lighthalzen", "hugel", "rachel", "prontera";
		setarray .@cost[0],         2200,          2200,    2200,     2200,       1800;

		.@size = getarraysize(.@towns$);
		for(.@i = 0; .@i<.@size; ++.@i)
			.@menu$ += .@towns$[.@i]+" -> "+.@cost[.@i]+"z:";
		.@i = select(.@menu$+"Cancel")-1;
		if (.@i == .@size)
			close;
		if (Zeny < .@cost[.@i]) {
				mes "[Isalei]";
			mes "I'm sorry, but you don't have";
			mes "enough zeny for the Teleport";
			mes "Service. The fee to teleport";
			mes "to "+.@towns$[.@i]+" is "+.@cost[.@i]+" zeny.";
			close;
		}
		specialeffect(EF_READYPORTAL, AREA, playerattached());
		specialeffect(EF_TELEPORTATION, AREA, playerattached());
		specialeffect(EF_PORTAL, AREA, playerattached());
		next;
		Zeny -= .@cost[.@i];
		switch(.@i) {
			case 0: warp "einbroch",67,195; break;
			case 1: warp "lighthalzen",159,90; break;
			case 2: warp "hugel",98,150; break;
			case 3: warp "rachel",119,135; break;
			case 4: warp "prontera",116,72; break;
		}
		close;
	case 2:
		close;
	}
}
