//================= Hercules Script =======================================
//=       _   _                     _
//=      | | | |                   | |
//=      | |_| | ___ _ __ ___ _   _| | ___  ___
//=      |  _  |/ _ \ '__/ __| | | | |/ _ \/ __|
//=      | | | |  __/ | | (__| |_| | |  __/\__ \
//=      \_| |_/\___|_|  \___|\__,_|_|\___||___/
//================= License ===============================================
//= This file is part of Hercules.
//= http://herc.ws - http://github.com/HerculesWS/Hercules
//=
//= Copyright (C) 2012-2015  Hercules Dev Team
//= Copyright (C)  Euphy
//= Copyright (C)  L0ne_W0lf
//=
//= Hercules is free software: you can redistribute it and/or modify
//= it under the terms of the GNU General Public License as published by
//= the Free Software Foundation, either version 3 of the License, or
//= (at your option) any later version.
//=
//= This program is distributed in the hope that it will be useful,
//= but WITHOUT ANY WARRANTY; without even the implied warranty of
//= MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//= GNU General Public License for more details.
//=
//= You should have received a copy of the GNU General Public License
//= along with this program.  If not, see <http://www.gnu.org/licenses/>.
//=========================================================================
//= Lighthalzen Guides (Renewal)
//================= Description ===========================================
//= Guides for the city of Lighthalzen.
//================= Current Version =======================================
//= 1.2
//=========================================================================

lighthalzen,207,310,5	script	Lighthalzen Guide#lhz01::GuideLighthazlen	4_M_EIN_SOLDIER,{
	cutin "ein_soldier",2;
	mes "[Lighthalzen Guide]";
	mes "Welcome to ^8B4513Lighthalzen^000000,";
	mes "the Corporation City-State.";
	mes "If you need any guidance";
	mes "around the city, feel free";
	mes "to ask me and I'll do my";
	mes "very best to help you.";
	next;
	mes "[Lighthalzen Guide]";
	mes "Please be aware that I'm";
	mes "in charge of providing info";
	mes "regarding the West District";
	mes "of ^8B4513Lighthalzen^000000. Now, please";
	mes "select the location that you'd";
	mes "like to learn more about.";
	F_Navi("[Lighthalzen Guide]");
	next;
	while (1) {
		switch(select("[ Main Facilities ]", "[ Merchants & Helpers ]", "Remove Marks from Mini-Map", "Cancel")) {
		case 1:
			.@loop = 1;
			while (.@loop) {
				switch(select("[ Hotel ]", "[ Bank ]", "[ Airport ]", "[ Weapon Shop ]", "[ Department Store ]", "[ Police Station ]", "[ Jewelry Store ]", "[ Cool Event Corp. ]", "[ Somatology Laboratory ]", "[ Alchemist Association ]", "Previous Menu")) {
				case 1:
					callsub L_Mark, F_Navi("Hotel","lighthalzen,159,133","^FF0000");
					viewpoint 1,160,217,0,0xFF0000;
					next;
					break;
				case 2:
					callsub L_Mark, F_Navi("Bank","lighthalzen,203,257","^FF4500");
					viewpoint 1,203,257,1,0xFF4500;
					next;
					break;
				case 3:
					callsub L_Mark, F_Navi("Airport","lighthalzen,262,75","^DAA520");
					viewpoint 1,262,75,2,0xDAA520;
					next;
					break;
				case 4:
					callsub L_Mark, F_Navi("Weapon Shop","lighthalzen,194,35","^7B68EE");
					viewpoint 1,194,35,3,0x7B68EE;
					next;
					break;
				case 5:
					callsub L_Mark, F_Navi("Department Store","lighthalzen,199,164","^B91A4D");
					viewpoint 1,202,106,4,0xB91A4D;
					next;
					break;
				case 6:
					callsub L_Mark, F_Navi("Police Station","lighthalzen,234,276","^008000");
					viewpoint 1,234,276,5,0x008000;
					next;
					break;
				case 7:
					callsub L_Mark, F_Navi("Jewelry Store","lighthalzen,96,110","^0000FF");
					viewpoint 1,96,110,6,0x0000FF;
					next;
					break;
				case 8:
					callsub L_Mark, F_Navi("Cool Event Corp.","lighthalzen,238,217","^000080");
					viewpoint 1,238,217,7,0x000080;
					next;
					break;
				case 9:
					callsub L_Mark, F_Navi("Somatology Laboratory","lighthalzen,101,243","^800080");
					viewpoint 1,101,243,8,0x800080;
					next;
					break;
				case 10:
					callsub L_Mark, F_Navi("Alchemist Association","lighthalzen,54,132","^0A9696");
					viewpoint 1,54,132,9,0x0A9696;
					next;
					break;
				case 11:
					.@loop = 0;
					break;
				}
			}
			break;
		case 2:
			.@loop = 1;
			while (.@loop) {
				switch(select("[ Armsmith ]", "[ Seiayablem ]", "[ Pet Groomer ]", "[ Kafra Employees ]", "[ Cool Event Corp. Staff ]", "Previous Menu")) {
				case 1:
					mes "[Lighthalzen Guide]";
					mes "You may go to Fulerr,";
					mes "the ^0A9696Armsmith^000000";
					mes "on the 1st floor of the Weapon Shop.";
					viewpoint 1,194,35,10,0x0A9696;
					next;
					callsub L_Mark, "^0A9696Armsmith^000000";
					next;
					break;
				case 2:
					mes "[Lighthalzen Guide]";
					mes "^4B0082Seiyablem^000000 adds";
					mes "sockets on your items";
					mes "on the 1st floor";
					mes "of the Weapon Shop.";
					viewpoint 1,194,35,11,0x4B0082;
					next;
					callsub L_Mark, "^4B0082Seiyablem^000000",1;
					next;
					break;
				case 3:
					callsub L_Mark, F_Navi("Pet Groomer","lighthalzen,222,191","^FF4500");
					viewpoint 1,222,191,12,0xFF4500;
					next;
					break;
				case 4:
					callsub L_Mark, "^008080Kafra Employees^000000";
					viewpoint 1,164,99,13,0x008080;
					viewpoint 1,164,99,14,0x008080;
					next;
					break;
				case 5:
					callsub L_Mark, F_Navi("Cool Event Corp. Staff","lighthalzen,94,247","^FF1493");
					viewpoint 1,94,247,15,0xFF1493;
					next;
					break;
				case 6:
					.@loop = 0;
					break;
				}
			}
			break;
		case 3:
			mes "[Lighthalzen Guide]";
			mes "Sure, I'll remove all marks from your mini-map.";
			mes "Is there anything else I can do for you?";
			viewpoint 2,160,217,0,0xFFFFFF;
			viewpoint 2,203,257,1,0xFFFFFF;
			viewpoint 2,262,75,2,0xFFFFFF;
			viewpoint 2,194,35,3,0xFFFFFF;
			viewpoint 2,202,106,4,0xFFFFFF;
			viewpoint 2,234,276,5,0xFFFFFF;
			viewpoint 2,96,110,6,0xFFFFFF;
			viewpoint 2,238,217,7,0xFFFFFF;
			viewpoint 2,101,243,8,0xFFFFFF;
			viewpoint 2,54,132,9,0xFFFFFF;
			viewpoint 2,194,35,10,0xFFFFFF;
			viewpoint 2,194,35,11,0xFFFFFF;
			viewpoint 2,222,191,12,0xFFFFFF;
			viewpoint 2,164,99,13,0xFFFFFF;
			viewpoint 2,164,99,14,0xFFFFFF;
			viewpoint 2,94,247,15,0xFFFFFF;
			next;
			break;
		case 4:
			mes "[Lighthalzen Guide]";
			mes "Enjoy your adventures!";
			close2;
			cutin "ein_soldier",255;
			end;
		}
	}
	end;
L_Mark:
	mes "[Lighthalzen Guide]";
	mes "I will mark the location";
	mes "of "+((getarg(1,0))?"":"the ")+getarg(0);
	mes "on your mini-map.";
	mes "Would you like to check any other locations?";
	return;
}
lighthalzen,220,310,3	duplicate(GuideLighthazlen)	Lighthalzen Guide#lhz02	4_M_EIN_SOLDIER
lighthalzen,154,100,5	duplicate(GuideLighthazlen)	Lighthalzen Guide#lhz03	4_M_EIN_SOLDIER
lighthalzen,307,224,3	duplicate(GuideLighthazlen)	Lighthalzen Guide#lhz04	4_M_EIN_SOLDIER
